AUTOGUARDAR CADA "x" SEGUNDOS

Pega esto en el módulo del libro (en ThisWorkbook):

Private Sub Workbook_BeforeClose(Cancel As Boolean)
PararReloj
End Sub

Private Sub Workbook_Open()
LanzarReloj
End Sub


Y esto otro en un módulo creado por ti:


Dim dtHoraSiguiente As Date

Sub LanzarReloj()
GuardarLibro
End Sub

Sub PararReloj()
'Desactivar el evento Ontime
On Error Resume Next
Application.OnTime dtHoraSiguiente, "GuardarLibro", , False
End Sub

Sub GuardarLibro()
'Guardar el libro actual
Application.DisplayAlerts = False
ThisWorkbook.Save
Application.DisplayAlerts = True
'Lanzar el siguiente evento 10 segundos después
dtHoraSiguiente = Now + (10 / 86400) 'Para guardar el libro cada 10 segundos
Application.OnTime dtHoraSiguiente, "GuardarLibro"
End Sub


Un saludo.


Fernando Arroyo
MS MVP - Excel

"ABEL" escribió en el mensaje news:03b101c3a9cd$4acdd8a0$
Buenas,
estoy trabajando con Excel 2000, y tengo una pagina de
Excel, y necesito que cada "x" segundos se guarde sóla,sin
dar a nada.la opcion de autoguardar no me vale,porque es
cada 5 minutos,necesito un periodo de tiempo menor.
¿como lo hago?
¿pueden contestar a mi mail: ?
gracias,
abel