Configuracion automática con ODBC

21/07/2003 - 23:19 por Franklin Flores | Informe spam
Hola grupo quisiera saber si es posible hacer que al momento de hacer un
instalador esta cree el odbc de conexión, o alguna forma de que lo haga
automaticamente sin tener que configurarlo manualmente. Espero ser claro en
lo que quiero hacer... y me ayuden si se puede hacer o no se puede.

De antemano gracias por su ayuda
 

Leer las respuestas

#1 Softjaen
22/07/2003 - 01:04 | Informe spam
"Franklin Flores" escribió:

quisiera saber si es posible hacer que al momento de hacer un
instalador esta cree el odbc de conexión, o alguna forma de que
lo haga automaticamente sin tener que configurarlo manualmente.
Espero ser claro en lo que quiero hacer...



Hola, Franklin:

Me imagino que lo que tú deseas es registrar de manera automática en el
sistema del cliente, un origen de datos con nombre (DSN), para que no haya
que crearlo manualmente mediante «Orígenes de datos (ODBC)» del Panel de
Control de Windows, porque crear el ODBC, es bastante más complicado. :-)

Si es así, con el siguiente código de ejemplo, vamos a crear un nuevo DSN de
sistema que utiliza el driver de Microsoft Access. Todo consiste en utilizar
la función API «SQLConfigDataSource» y establecer los atributos apropiados,
dependiendo del driver que se desee utilizar.

Comienza un nuevo proyecto e inserta un «CommandButton» en el formulario de
inicio. Pega el siguiente código en la sección «Declaraciones» del
formulario:

Private Declare Function SQLConfigDataSource Lib "ODBCCP32.DLL" _
(ByVal hwndParent As Long, ByVal fRequest As Long, _
ByVal lpszDriver As String, ByVal lpszAttributes As String) _
As Long

Private Sub Command1_Click()

Dim sRutaBaseDatos As String
Dim sAttributes As String
Dim sDriver As String
Dim sNombre_DSN As String
Const ODBC_ADD_SYS_DSN = 4

' Parámetros necesarios: nombre DSN, ruta y driver
sNombre_DSN = "Ejemplo_DSN_Sistema"
sRutaBaseDatos = "C:\Mis documentos\Bd1.mdb"
sDriver = "Microsoft Access Driver (*.mdb)"

' Atributos
sAttributes = "DSN=" & sNombre_DSN & Chr(0)
sAttributes = sAttributes & "DBQ=" & sRutaBaseDatos & Chr(0)

' Creamos un origen de datos de sistema con el
' driver de Microsoft Access
SQLConfigDataSource 0&, ODBC_ADD_SYS_DSN, sDriver, sAttributes

End Sub

Eso es todo.

Un saludo.

Enrique Martínez
[MS MVP - VB]

Preguntas similares