Eliminar filas

Hola Age,

Tal como lo describes, creo que te deberia bastar con el siguiente codigo:

Sub QuitarFilasVacias1()
Dim Fila As Long
Application.ScreenUpdating = False
With ActiveSheet
For Fila = .Cells(.Rows.Count, "A").End(xlUp).Row To 1 Step -1
If IsEmpty(.Cells(Fila, "A")) Then .Rows(Fila).Delete
Next
End With
Application.ScreenUpdating = True
End Sub

Sin embargo tu macro dice otra cosa. Si eso es lo que quieres, prueba el
codigo que te pongo mas abajo:

Sub QuitarFilasVacias2()
Dim Fila As Long, Sh As Worksheet, rng As Range, UFila As Long
Set Sh = ActiveSheet: Set rng = Sh.Cells
On Error Resume Next
UFila = Intersect( _
rng.Find("*", rng(1), xlValues, xlWhole, xlByRows, _
xlPrevious).EntireRow, _
rng.Find("*", rng(1), xlValues, xlWhole, xlByColumns, _
xlPrevious).EntireColumn).Row
With Application
.ScreenUpdating = False
For Fila = UFila To 1 Step -1
If (.Count(Sh.Rows(Fila)) + _
.CountIf(Sh.Rows(Fila), "?*")) = 0 Then
Sh.Rows(Fila).Delete
End If
Next
.ScreenUpdating = True
End With
End Sub

Saludos,
KL




"Age" wrote in message
news:

Hola!

Quisiera pedirles ayuda, en una cedula que estoy haciendo... como
explicarlo:

a1 es donde ingreso mis dato de manera manuel

b1 siguiente formula =SI(ESERROR(BUSCARV($A202,'Catalogo
Empleados'!$A$4:$G$499,3,0)),"",BUSCARV($A202,'Catalogo
Empleados'!$A$4:$G$499,3,0))

Por lo tanto si en a1 no tengo dato en b1 no aparce nada.

quiero aplicar este macro:

Sub QuitarFilasVacias()


Dim Fila As Integer

Application.ScreenUpdating = False
For Fila = ActiveCell.SpecialCells(xlLastCell).Row To 1 Step -1
If Cells(Fila, 1).Value = "" And Cells(Fila, 1).End(xlToRight).Column > 256 Then
Cells(Fila, 1).EntireRow.Delete
End If
Next
Application.ScreenUpdating = True
End Sub

********************************

estoy aplicando este macro para eliminar las filas vacias, pero como
realmente no estan vacias ya que contienen las fomrulas , ?que
midificaciones
debo hacerle o que nuevo macro puden generarse, para que en caso de que en
a1
este vacio, toda la fila sea eliminada?

Gracias