ENTRE DOS CONCEPTOS

Hola Jorge,

1) Prueba las siguientes formulas:

=BUSCAR(A1;{0;20;26;31};{5,12;13,43;17,24;24,03})
=ELEGIR(COINCIDIR(A1;{0;20;26;31});5,12;13,43;17,24;24,03)
=INDICE({5,12;13,43;17,24;24,03};COINCIDIR(A1;{0;20;26;31}))
=BUSCARV(A1;{0\5,12;20\13,43;26\17,24;31\24,03};2)

2) Tambien podrias crear una tabla como la siguiente en una hoja y usarla en las formulas. Supongamos que el rango [A1:B4] de la hoja Hoja2 contiene los siguientes datos:

0 5,12
20 13,43
26 17,24
31 24,03

entonces podrias usar las siguientes formulas:

=BUSCARV(A1;Hoja2!$A$1:$B$4;2)
=BUSCAR(A1;Hoja2!$A$1:$A$4;Hoja2!$B$1:$B$4)
=INDICE(Hoja2!$B$1:$B$4;COINCIDIR(A1;Hoja2!$A$1:$A$4))
=ELEGIR(COINCIDIR(A1;Hoja2!$A$1:$A$4);5,12;13,43;17,24;24,03)

3) Podrias ponerle a la tabla de arriba un nombre atraves del menu Insertar>Nombre>Definir..., digamos "Tabla", y usar lo asi:

=BUSCARV(A1;Tabla;2)
=BUSCAR(A1;INDICE(Tabla;;1);INDICE(Tabla;;2))
=INDICE(INDICE(Tabla;;2);COINCIDIR(A1;INDICE(Tabla;;1)))
=ELEGIR(COINCIDIR(A1;INDICE(Tabla;;1));5,12;13,43;17,24;24,03)

4) En vez de crear una tabla podrias crear un nombre definido como el del punto 3 ("Tabla") pero en vez de un rango (=Hoja2!$A$1:$B$$) asociarlo a la formula ={0\5,12;20\13,43;26\17,24;31\24,03} y luego usar las mismas formulas del punto 3.


Saludos,
KL


"Jorge G" <Jorge wrote in message news:

Hola Chicos! ¿Cómo estais?
Tengo una consultilla
Como puedo decirle a excel que me indique si coincide con una escala de
valores.
Me explico:
Tengo que comparar si una celda coincide con los datos de una tabla que se
muestra del siguiente modo:
20 - 25 / 26 - 30 / 31 - 35 (es decir, de 20 a 25 en una columna, de 26 a
30...).
cada porción corresponde a un concepto, por ejemplo; si la celda se expone
22 el valor correcto es 13.43€ y el valor cambio dependiendo el dato.

Lo intento realizar con una condicion pero son tantas pociones que no me
caben en una Formula.
=SI(a1 ;0;Si(a1<25;13.43;... y asi con cada uno...

Para acotar la formula como podria decirle al sistema entre 20 y 25 por
ejemplo...

Gracias,
Jorge G