Insertar campos de propiedades

Para listar en Hoja1 a partir de A1 las propiedades del libro:

Sub ListarBuiltinDocumentProperties()
On Error GoTo ManejoErrores
Dim dpLibro As DocumentProperties
Dim n As Byte, strDatos As String
Set dpLibro = ThisWorkbook.BuiltinDocumentProperties

For n = 1 To dpLibro.Count
Worksheets("Hoja1").Range("A" & n) = dpLibro.Item(n).Name & ":"
Worksheets("Hoja1").Range("B" & n) = dpLibro.Item(n).Value
Next n

Set dpLibro = Nothing

Exit Sub

ManejoErrores:
If Err.Number = -2147467259 Then
Resume Next
Else
MsgBox prompt:="Error " & Err.Number & " " & Err.Description
End If
End Sub

(Cuidado, porque al ejecutar el código anterior se borrará lo que haya en A1:B30)


Para que en la sección central del encabezado de Hoja1 aparezcan el autor, la fecha y hora de la última modificación y el nombre de la compañía:

Sub PonerPropiedadesDeDocumentoEnEncabezado()
With ThisWorkbook.BuiltinDocumentProperties
Worksheets("Hoja1").PageSetup.CenterHeader = "Autor: " & .Item(3) & vbCr & "Última modificación " & .Item(12) & vbCr & "Compañía: " & .Item(21)
End With
End Sub

Un saludo.


Fernando Arroyo
MS MVP - Excel


"Gonzalo.cl" escribió en el mensaje news:12e801c3fba4$5a854e80$
¿Como puedo insertar los campos de las propiedades del
documento en una hoja Excel?
¿Y en el encabezado y pié de página?
Por ejemplo: autor, ultima modificación, organización,
etc...

Gracias.