OpenFilesDialog

14/08/2006 - 18:25 por JReyes | Informe spam
VB2005

Como utilizar el OpenFilesDialog para seleccionar archivos de un directorio
y colocarlos en un DataGridView.

Gracias de antemano
 

Leer las respuestas

#1 SoftJaén
14/08/2006 - 18:57 | Informe spam
"JReyes" preguntó:

Como utilizar el OpenFilesDialog para seleccionar archivos
de un directorio y colocarlos en un DataGridView.



Bueno, son dos cosas bien distintas. Primero deberás abrir el cuadro de
diálogo para seleccionar los archivos, y después, tendrás que crear un
objeto DataTable, con sus correspondientes registros (que serán los nombres
de los archivos), y añadir el DataTable a un objeto DataSet para
posteriormente asociarlo al control DataGridView. Adapta el siguiente
ejemplo a tus necesidades.

Primero, seleccionamos los archivos:

Dim dlg As New OpenFileDialog

With dlg
' Permitimos la selección múltiple
' de archivos.
.Multiselect = True

' Visualizamos el cuadro de diálogo
Dim r As DialogResult = .ShowDialog

If r = Windows.Forms.DialogResult.OK Then
' Mostramos los archivos en el
' control DataGridView
'
ShowDataGridView(.FileNames)
End If
End With

Segundo, creamos los objetos correspondientes para mostrar los archivos en
el control DataGridView:

Private Sub ShowDataGridView(ByVal fileNames() As String)

' Creamos un objeto DataTable, configurando su
' capacidad inicial, y no diferenciando entre
' mayúsculas o minúsculas.
'
Dim dt As New DataTable
With dt
.TableName = "Archivos"
.MinimumCapacity = 200
.CaseSensitive = False
End With

' Creamos una columna, y la añadimos
' al objeto DataTable.
'
Dim dc As DataColumn

dc = New DataColumn("Archivo", GetType(String))
dc.MaxLength = 256
dt.Columns.Add(dc)

' Recorremos la colección de archivos,
' creando con ellos nuevos registros
'
Dim file As String

For Each file In fileNames
Dim dr As DataRow = dt.NewRow

' Añadimos los datos
dr.Item("Archivo") = file

' Agregamos el registros a la colección Rows
dt.Rows.Add(dr)
Next

' Creamos un objeto DataSet
'
Dim ds As New DataSet

' Añadimos la tabla al objeto DataSet
'
ds.Tables.Add(dt)

' Configuramos el control DataGridView
With DataGridView1
.DataSource = ds
.DataMember = "Archivos"
End With

End Sub

Eso es todo.

Un saludo

Enrique Martínez
[MS MVP - VB]

Nota informativa: La información contenida en este mensaje, así como el
código fuente incluido en el mismo, se proporciona «COMO ESTÁ», sin
garantías de ninguna clase, y no otorga derecho alguno. Usted asume
cualquier riesgo al poner en práctica, utilizar o ejecutar lo recomendado o
sugerido en el presente mensaje.

Preguntas similares