ordenar alfabetico de hojas - responder a esta casilla

Prueba con el siguiente código:

Sub OrdenarHojas()
Dim wksH As Worksheet

Dim mtrHojas() As String
Dim intBucle As Integer
Dim blnOrdenado As Boolean
Dim strCambio As String

ReDim mtrHojas(1 To ThisWorkbook.Worksheets.Count)

For Each wksH In ThisWorkbook.Worksheets
mtrHojas(wksH.Index) = wksH.Name
Next

Do
blnOrdenado = True

For intBucle = 1 To UBound(mtrHojas) - 1

If mtrHojas(intBucle) > mtrHojas(intBucle + 1) Then
strCambio = mtrHojas(intBucle)
mtrHojas(intBucle) = mtrHojas(intBucle + 1)
mtrHojas(intBucle + 1) = strCambio
blnOrdenado = False
Exit For
End If

Next intBucle

If blnOrdenado Then Exit Do
Loop

Application.ScreenUpdating = False
For intBucle = UBound(mtrHojas) To LBound(mtrHojas) Step -1
Sheets(mtrHojas(intBucle)).Move before:=Sheets(1)
Next intBucle
Application.ScreenUpdating = True

Set wksH = Nothing
End Sub


Un saludo.


Fernando Arroyo
MS MVP - Excel



"CHECHU" escribió en el mensaje news:39e401c4a635$aa0af9a0$
Buenos días para todos:
Tengo un libro de excel que posee 140 hojas y cuando
preciso una nueva la agrego al final, sin percatarme del
orden alfabetico.
El problema se presenta cuando tengo que consultar alguna
de ellas. Se me complica para buscarlas
Alli esta la pregunta: se puede buscar rapidamente por
nombre de hoja (etiqueta)?, ó como hago para ordenarlas
alfabeticamente??
Desde ya muchas gracias
CHECHU