ayuda sobre grid

23/05/2006 - 18:49 por WILLIAMS | Informe spam
Hola alguien podria yudarme a resolver un problemita
es asunto es que tengo un grid y en el necesito restringir el ingreso de
ciertos datos
como por ejemplo lograr que solo acepte ciertos caracteres, o ciertas
cantidades

agradesco su ayuda de antemano
gracias

Preguntas similare

Leer las respuestas

#1 Dario David Puccio
24/05/2006 - 14:51 | Informe spam
Tendrias que colocar una validacion en el valid del text de la columna a
considerar.

Dario
Respuesta Responder a este mensaje
#2 WILLIAMS
25/05/2006 - 20:21 | Informe spam
ya esta bien perocomo hago si creo el grid en tiempo de ejecucion lo que
pasa es que debo adecuarle el numero de las columnas... y cuando hago eso...
en que parte debo de agregar o hacr la validacion

gracias



"Dario David Puccio" escribió en el mensaje
news:%
Tendrias que colocar una validacion en el valid del text de la columna a
considerar.

Dario


Respuesta Responder a este mensaje
#3 Dario David Puccio
26/05/2006 - 21:40 | Informe spam
Estimo que primero agregas el objeto grid , luego dentro del define class
del grid que haces cuando defines los procedures de las columnas... lo
siento si no puedo ayudarte mas, yo trabajo todo sobre el form
con los objetos no los programo...

Dario
Respuesta Responder a este mensaje
#4 Mario López
27/05/2006 - 15:32 | Informe spam
Williams:

podés usar clases de textbox con validación definible:

-
CLOSE TABLES ALL
USE HOME() + "Samples\Tastrade\Data\products.dbf"

SET MULTILOCKS ON
CURSORSETPROP("Buffering", 5)

PUBLIC frmTest
frmTest = CREATEOBJECT("xForm")
frmTest.Show()

RETURN



DEFINE CLASS xForm as Form
ADD OBJECT grdProd as Grid WITH ;
Top = 10, Left = 10, Width = 500, Height = 200

Width = 520

PROCEDURE Init

* Agrego los textbox de validación
WITH This.grdProd
FOR nCols = 1 TO .ColumnCount
WITH .Columns (nCols)
.AddObject ("txtValidTextBox", "xValidTextBox")
.CurrentControl = "txtValidTextBox"
.txtValidTextBox.Visible = .T.
ENDWITH
NEXT

* Ahora puedo asignar una validación particular a cada columna:
* ej: la columna 1 no puede ser 0
WITH .Columns(1).txtValidTextBox
.ValidExpr = [VAL(This.Value) <> 0]
.ValidMessage = "Debe indicar valor"
ENDWITH
ENDWITH

ENDPROC
ENDDEFINE


* TextBox con validación
DEFINE CLASS xValidTextBox as TextBox
ValidExpr = [.T.] && Expresión a validar
ValidMessage = "" && Mensaje de error
Margin = 0

PROCEDURE Valid

LOCAL xRet
xRet = EVALUATE(This.ValidExpr)
IF ! xRet
MESSAGEBOX(This.ValidMessage, 16)
ENDIF

RETURN xRet
ENDDEFINE
-

En caso de necesitar algún otro control que no sea un textbox tendrías que definir otra clase (ej: xValidComboBox, etc)
de la misma forma.

HTH
Mario

On Thu, 25 May 2006 13:21:00 -0500, "WILLIAMS" wrote:

ya esta bien perocomo hago si creo el grid en tiempo de ejecucion lo que
pasa es que debo adecuarle el numero de las columnas... y cuando hago eso...
en que parte debo de agregar o hacr la validacion

gracias



"Dario David Puccio" escribió en el mensaje
news:%
Tendrias que colocar una validacion en el valid del text de la columna a
considerar.

Dario





Respuesta Responder a este mensaje
#5 WILLIAMS
29/05/2006 - 15:48 | Informe spam
ok gracias por la ayuda a todos
digamos que siempre existen carios caminos para poder llegar a tu
destimo



"WILLIAMS" escribió en el mensaje
news:%
ya esta bien perocomo hago si creo el grid en tiempo de ejecucion lo


que
pasa es que debo adecuarle el numero de las columnas... y cuando hago


eso...
en que parte debo de agregar o hacr la validacion

gracias



"Dario David Puccio" escribió en el mensaje
news:%
> Tendrias que colocar una validacion en el valid del text de la columna a
> considerar.
>
> Dario
>
>


email Siga el debate Respuesta Responder a este mensaje
Ads by Google
Help Hacer una preguntaRespuesta Tengo una respuesta
Search Busqueda sugerida