Consulta a KL

Hola Roberto,

A ver, si te he entendido bien... Una forma podria ser la de proteger la hoja y usar el siguiente codigo (fijate en que uso diferentes claves para protejer la hoja y validar el derecho a modificar la celda):

'-en el modulo ThisWorkbook-
Private Const PASS = "miclave1"

Private Sub Workbook_Open()
Worksheets(1).Protect Password:=PASS, userinterfaceonly:=True
End Sub
'-en el modulo ThisWorkbook-

y

'-en el modulo de la hoja--
Private Const PASS = "miclave2"
Private celda As Range

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Me.ProtectContents Then Exit Sub
If Target.Locked = False Then Exit Sub
Application.DisplayAlerts = False
If InputBox("introduzca la clave:") = PASS Then
Target.Locked = False
Set celda = Target
Else
Cancel = True
MsgBox "No esta autorizado a modificar la hoja"
End If
Application.DisplayAlerts = True
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
If celda Is Nothing Then Exit Sub
If Intersect(Target, celda) Is Nothing Then Exit Sub
celda.Locked = True
End Sub
'-en el modulo de la hoja--

Seguramente Hector Miguel vendra con algo mas eficiente, que el es un experto en la seguridad.

Saludos,
KL


"CONTADURIA" wrote in message news:%

KL: me intereso mucho la idea de trabar hojas
para evitar modificaciones posteriores. Se podria evitar mediante codigo de
VBA que se modifique una hoja de trabajo?. En caso positivo existira la
posibilidad de que al intentar modificar la hoja pregunte una contraseña
para modificar?.
Desde ya muchas gracias y espero turespuesta.
Roberto