Contar celdas en un filtro

Prueba esta fórmula matricial:

{=SUMA(1*(SI(SUBTOTALES(3;DESREF($A$2;FILA($A$2:A2)-FILA($A$2);0));1;0)))}

Funcionará si colocas en cualquier columna de la fila 2. Cópiala hacia
abajo hasta el último registro, y cuando pases algún filtro, debería
recalcularse automáticamente, devolviendo las filas (registros) 'visibles'.

:-)



Eva wrote:

Saludos al grupo.

Alguien me podría orientar como contar las celdas de un rango "visible"
determinado
que cumplen una serie de condiciones en un filtro?

Me explico:
Tengo una lista con notas de 1 a 10 con distintos alumnos y distintas
materias; hago un filtro para seleccionar a un alumno
y me gustaría que la función contar.si sólo me contara los 1, 2, 3...10 de
ese alumno visible.

Gracias: Eva

Hola chicos,

Se puede ahorrar el rollo de crear una colu,na adicional y copiar las formulas para cada una de las filas y ademas evitar formulas
matricialesde la siguiente manera:

1) Suponiendo que:
- las notas estan en la columna B de una tabla cuyos datos (todavia sin filtrar) se encuentran entre las filas 2 y 10 (ambas
incluidas)
- se quiere contar la nota 8 para un alumno filtrado

entonces
=SUMAPRODUCTO(($B$2:$B$10=8)*(SUBTOTALES(2;DESREF($B$2;FILA($B$2:$B$10)-FILA(INDICE($B$2:$B$10;1));))))
o
=SUMAPRODUCTO(($B$2:$B$10=8)*(SUBTOTALES(2;DESREF($B$2;FILA($B$2:$B$10)-FILA($B$2);))))
o
=SUMAPRODUCTO(($B$2:$B$10=8)*(SUBTOTALES(2;DESREF($B$2;FILA($B$2:$B$10)-2;))))

2) Suponiendo que:
- las notas estan en la columna B de una tabla cuyos datos (todavia sin filtrar) se encuentran entre las filas 2 y 10 (ambas
incluidas)
- se quiere contar solo las notas 1, 2 y 8 para un alumno filtrado

entonces
=SUMAPRODUCTO(($B$2:$B$10={1\2\8})*(SUBTOTALES(2;DESREF($B$2;FILA($B$2:$B$10)-FILA(INDICE($B$2:$B$10;1));))))
o
=SUMAPRODUCTO(($B$2:$B$10={1\2\8})*(SUBTOTALES(2;DESREF($B$2;FILA($B$2:$B$10)-FILA($B$2);))))
o
=SUMAPRODUCTO(($B$2:$B$10={1\2\8})*(SUBTOTALES(2;DESREF($B$2;FILA($B$2:$B$10)-2;))))

3) Suponiendo que:
- las notas estan en la columna B de una tabla cuyos datos (todavia sin filtrar) se encuentran entre las filas 2 y 10 (ambas
incluidas)
- no hay notas 0
- se quiere contar todas las notas para un alumno filtrado

entonces
=SUBTOTALES(2;$B$2:$B$10)

Saludos,
KL


""Víctor"" wrote in message news:etceq%

Prueba esta fórmula matricial:

{=SUMA(1*(SI(SUBTOTALES(3;DESREF($A$2;FILA($A$2:A2)-FILA($A$2);0));1;0)))}

Funcionará si colocas en cualquier columna de la fila 2. Cópiala hacia
abajo hasta el último registro, y cuando pases algún filtro, debería
recalcularse automáticamente, devolviendo las filas (registros) 'visibles'.

:-)



Eva wrote:

Saludos al grupo.

Alguien me podría orientar como contar las celdas de un rango "visible"
determinado
que cumplen una serie de condiciones en un filtro?

Me explico:
Tengo una lista con notas de 1 a 10 con distintos alumnos y distintas
materias; hago un filtro para seleccionar a un alumno
y me gustaría que la función contar.si sólo me contara los 1, 2, 3...10 de
ese alumno visible.

Gracias: Eva