Indicar Duplicados

Que tal Luis,.. aqui te adlanto algo mientras llega mas sabiduria, de
nuestros amigos y maestros
Coloca esta formula en la celda B2 y la copias hacia abajo hasta la celda
A1000 y nos comentas lo que esta en comillas, si gusas lo cambias a 1

=SI(CONTAR.SI(A:A,A2)>1,"REPETIDO","")

Jesús Peralta
el_ultimo_profeta"alt+64"hotmail.com
Hermosillo, Sonora. Mexico
"Luis" escribió en el mensaje
news:
Qué tal??!! Tengo un pequeño problema, en una hoja de excel tengo
desde la celda A2 hasta A1000 varios Nombres, deseo ver si mediante
FÓRMULAS existe la posibilidad de indicar (por ejemplo con un número 1
en la columna B) si cada uno de los nombres está duplicado en el
listado y en el caso de que lo esté mostrar (en la celda C por
ejemplo) la fila en la que se encuentra el duplicado. Sé que es
posible hacerlo por macros pero sería muy interesante lograrlo
mediante fórmulas.

Saludos y Muchas Gracias!!!

Hola Luis,

...desde la celda A2 hasta A1000 varios Nombres,...
...mediante FÓRMULAS...
...indicar (por ejemplo con un número 1
en la columna B) si cada uno de los nombres está duplicado en el
listado y en el caso de que lo esté mostrar (en la celda C por
ejemplo) la fila en la que se encuentra el duplicado.

Opcion 1: Marca en la columna [B]

a. los duplicados excluidos los que aparecen primeros
en [B2] pon la siguiente formula y copiala hacia abajo:
=--(CONTAR.SI(A$2:A2;A2)>1)

b. todos los duplicados
en [B2] pon la siguiente formula y copiala hacia abajo:
=--(CONTAR.SI(A$2:A$1000;A2)>1)

Opcion 2: Formato Condicional

a. los duplicados excluidos los que aparecen primeros
- selecciona el rango [A2:A1000] (empezando desde [A2])
- menu Formato>Formato Condicional...
- en el 1er desplegable de la Condicion1 elige: 'Formula es'
- en el cuadro de formula escribe: =CONTAR.SI(A$2:A2;A2)>1
- boton: Formato
- elige el formato que te guste, digamos la trama de color rojo.
- pulsa Aceptar, Aceptar

b. todos los duplicados
sigue el procedimiento anterior cambiando la formula a: =CONTAR.SI(A$2:A$1000;A2)>1

Opcion 3: Lista de numeros de fila con duplicados en la columna [C]

en la celda [C2] pon la siguiente formula MATRICIAL (se introduce mediante CTRL+SHIFT+ENTER) y copiala hacia abajo:

{=K.ESIMO.MENOR(SI($A$2:$A$1000<>"";SI((FILA($A$2:$A$1000)-FILA($A$2)+1)<>COINCIDIR($A$2:$A$1000;$A$2:$A$1000;0);FILA($A$2:$A$1000)));FILA(A1))}

Saludos,
KL

Excelente!!! Muchas Gracias!!! He podido identificar cuales son los
repetidos peeero tengo un pequeño problema y es que no puedo ingresar
la fórmula para identificar la fila del duplicado pues al ingresarla
simplemente la toma como un texto y si antepongo un igual me sale
error ¿?¿?¿?¿? (cabe indicar que modifiqué la fórmula con mi separador
de listas que es la coma), ahh y si utilicé CTRL+SHIFT+ENTER... Bueno
también tengo otra consulta y es ¿qué significa o para qué sirve "--"
antes de una función???

Muchas Gracias por su ayuda y por su tiempo!

Hola Luis,

"Luis" wrote in message news:
Excelente!!! Muchas Gracias!!! He podido identificar cuales son los
repetidos peeero tengo un pequeño problema y es que no puedo ingresar
la fórmula para identificar la fila del duplicado pues al ingresarla
simplemente la toma como un texto y si antepongo un igual me sale
error ¿?¿?¿?¿? (cabe indicar que modifiqué la fórmula con mi separador
de listas que es la coma), ahh y si utilicé CTRL+SHIFT+ENTER... Bueno
también tengo otra consulta y es ¿qué significa o para qué sirve "--"
antes de una función???

1) Creo que el problema esta en que he incluido los corchetes alrededor de la formula. Quitalos e intenta ingresar la formula de
nuevo:

=K.ESIMO.MENOR(SI($A$2:$A$1000<>"",SI((FILA($A$2:$A$1000)-FILA($A$2)+1)<>COINCIDIR($A$2:$A$1000,$A$2:$A$1000,0),FILA($A$2:$A$1000))),FILA(A1))

2) Revisa esto:

http://tinyurl.com/ypro5w
http://www.mcgimpsey.com/excel/form...leneg.html

Saludos,
KL