nombre de archivo en celda

Hola Alejandro,

Prueba las siguientes formulas:

Ruta:
=IZQUIERDA(CELDA("filename";A1);ENCONTRAR("[";CELDA("filename";A1))-1)

Nombre Archivo:
=EXTRAE(CELDA("filename";A1);ENCONTRAR("[";CELDA("filename";A1))+1;ENCONTRAR("]";CELDA("filename";A1))-ENCONTRAR("[";CELDA("filename";A1))-1)

Nombre Hoja:
=EXTRAE(CELDA("filename";$A$1);ENCONTRAR("]";CELDA("filename";$A$1);1)+1;LARGO(CELDA("filename";$A$1)))

si tambien quieres que tu formula este a prueba de una situacion un tanto particular de cuando el libro solo tiene una hoja y el nombre de esa es exactamente el mismo que el del libro, entonces usa la siguiente solucion un pelin mas larga:

=BUSCAR(REPETIR("z";255);SUSTITUIR(EXTRAE(CELDA("filename";$A$1);1+ENCONTRAR({"*"\"]"};SUSTITUIR(CELDA("filename";$A$1);"\";"*";LARGO(CELDA("filename";$A$1))-LARGO(SUSTITUIR(CELDA("filename";$A$1);"\";""))));255);".xls";""))

Si no me equivoco, las formulas deberian funcionar en el Office en castellano aun usando el argumento "filename" (entonces las formulas serian compatibles con las versiones de Office en otros idiomas) De no ser asi, cambia "filename" por "nombrearchivo".

Saludos,
KL



"Alejandro" wrote in message news:

Amigos, necesito saber como puedo colocar el nombre del archivo en una celda,
existe alguna función para eso?
Lo mismo para la ruta de acceso (directorios donde está guardado el archivo
excel.)

Gracias,

Edhin

Lo puedes hacer de estas dos maneras

Range("A1") = ActiveWorkbook.Name
ActiveCell.Value = ActiveWorkbook.Name

Atte.
?T Francisco T?
http://groups.msn.com/dadyboy

"El progreso debe ser un movimiento ordenado y racional hacia una meta
fija... y no un torbellino de direcciones falsas y encontradas."

"KL" Eres admirable con el manejo de fórmulas porque todo lo puedes hacer
creando tus fórmulas para cada caso especial es verdadramente admirable, me
quedo impresionadísimo. Y me pregunto yo habrá una manera de estudir algo
para llegar a dominar este asunto aunque sea en una mínima parte de lo que tu
logras, ¿Qué me recomiendad habrá algún curso o algo asi, porque es muy
bonito preguntarte y que nos saques del apuro pero y cuando se le ofrece a
uno hacerlo y tu no estás, cómo le hacemos? Pero por lo pronto ojalá que
estés dispuesto a seguir con tu valiosa ayuda, muchas gracias.

"KL" escribió:

Hola Alejandro,

Prueba las siguientes formulas:

Ruta:
=IZQUIERDA(CELDA("filename";A1);ENCONTRAR("[";CELDA("filename";A1))-1)

Nombre Archivo:
=EXTRAE(CELDA("filename";A1);ENCONTRAR("[";CELDA("filename";A1))+1;ENCONTRAR("]";CELDA("filename";A1))-ENCONTRAR("[";CELDA("filename";A1))-1)

Nombre Hoja:
=EXTRAE(CELDA("filename";$A$1);ENCONTRAR("]";CELDA("filename";$A$1);1)+1;LARGO(CELDA("filename";$A$1)))

si tambien quieres que tu formula este a prueba de una situacion un tanto particular de cuando el libro solo tiene una hoja y el nombre de esa es exactamente el mismo que el del libro, entonces usa la siguiente solucion un pelin mas larga:

=BUSCAR(REPETIR("z";255);SUSTITUIR(EXTRAE(CELDA("filename";$A$1);1+ENCONTRAR({"*"\"]"};SUSTITUIR(CELDA("filename";$A$1);"\";"*";LARGO(CELDA("filename";$A$1))-LARGO(SUSTITUIR(CELDA("filename";$A$1);"\";""))));255);".xls";""))

Si no me equivoco, las formulas deberian funcionar en el Office en castellano aun usando el argumento "filename" (entonces las formulas serian compatibles con las versiones de Office en otros idiomas) De no ser asi, cambia "filename" por "nombrearchivo".

Saludos,
KL



"Alejandro" wrote in message news:
> Amigos, necesito saber como puedo colocar el nombre del archivo en una celda,
> existe alguna función para eso?
> Lo mismo para la ruta de acceso (directorios donde está guardado el archivo
> excel.)
>
> Gracias,
>
> Edhin
>
>