Suma de eventos

Hola Javier,

Suponiendo que [J11]=3 y [J12]=6, entonces

1) Si quieres CONTAR los valores con dos criterios del tipo q expones,
puedes usar las siguientes formulas:


=(CONTAR.SI(J6:J10,"<="&J12))-(CONTAR.SI(J6:J10,"<="&J11))
o
=SUMAPRODUCTO((J6:J10<=J12)*(J6:J10>J11))

2) Si quieres SUMAR los valores con dos criterios del tipo q expones, puedes
usar las siguientes formulas:

=(SUMAR.SI(J6:J10,"<="&J12,J6:J10))-(SUMAR.SI(J6:J10,"<="&J11,J6:J10))
o
=SUMAPRODUCTO((J6:J10<=J12)*(J6:J10>J11)*J6:J10)

3) Si quieres SUMAR valores en otra columna (digamos [K]) si los valores en
la columna [J] cumplen con los criterios del tipo q expones, puedes usar las
siguientes formulas:

=(SUMAR.SI(J6:J10,"<="&J12,K6:K10))-(SUMAR.SI(J6:J10,"<="&J11,K6:K10))
o
=SUMAPRODUCTO((J6:J10<=J12)*(J6:J10>J11)*K6:K10)

Saludos,
KL

"Javier Rios" wrote in message
news:

Tengo un problema en excel,
Tengo que contar celdas que contienen valores iguales...
Utilizando =(CONTAR.SI(J6:J10,"<="&J11)) obtengo el resultado que deseo,
incluso utilizo valores que especifico en la celda J11 el caso es que
quiero
sumar celdadas pero en rangos es decir >3 y <=6 y no me sale, alguen me
puede
ayudar...
Gracias.