SumaProducto()

Hola Angelo,

No se cual era tu intencion, pero lo que estas evaluando entre otras cosas
es si las celdas en el rango LD!B$3:B$32 equivalen a "[ Llamadas de Larga
Distancia Internacional en Promo ]" y "[ Llamadas de Larga Distancia
Internacional ]" a la vez (!!!). Y una celda no puede tener dos valores a la
vez :-(

Si quieres que te sume los registros correspondientes TANTO SI las celdas en
el rango LD!B$3:B$32 equivalen a "[ Llamadas de Larga Distancia
Internacional en Promo ]" COMO "[ Llamadas de Larga Distancia
Internacional ]" entonces:

1) usa el operador mas (+):

=SUMAPRODUCTO((LD!C$3:D$32)*((LD!B$3:B$32="[ Llamadas de Larga Distancia
Internacional en Promo ]")+(LD!B$3:B$32="[ Llamadas de Larga Distancia
Internacional ]"))*(LD!A$3:A$32=Plantilla!B7))

2) o matriz fija:

=SUMAPRODUCTO((LD!C$3:D$32)*(LD!B$3:B$32={"[ Llamadas de Larga Distancia
Internacional en Promo ]","[ Llamadas de Larga Distancia
Internacional ]"})*(LD!A$3:A$32=Plantilla!B7))

Saludos,
KL



"Angelo Vernaza" wrote in message
news:

Buenas Tardes, Cómo estan?

Estoy tratando de usar la siguiente fórmula pero no me suma nada, quisiera
saber donde tengo el error:

=SUMAPRODUCTO((LD!C$3:D$32)*(LD!B$3:B$32="[ Llamadas de Larga Distancia
Internacional en Promo ]")*(LD!B$3:B$32="[ Llamadas de Larga Distancia
Internacional ]")*(LD!A$3:A$32=Plantilla!B7))

Donde:
LD!C$3:D$32 = Valores a Sumar
LD!B$3:B$32 = Lista a comparar con las condiciones
LD!A$3:A$32 = Otra lista para buscar otra condición

espero me puedan ayudar.

Saludos,