crear tabla desde visual

"Alejandro" escribió:

tengo un problema, necesito crear una tabla
de access 97 desde visual basic 5.0.

no se como ademas de esto, crealos con el formato que yo
quiera, ej:

al crear dbinteger, quiero que sea entero largo
al crear dbdate, quiero que sea fecha corta.

Hola, Alejandro:

Si estas utilizando la biblioteca de DAO, para especificar un campo tipo
entero largo, en lugar del valor «dbInteger» utilizar «dbLong». En cuanto al
formato de fecha corta, una vez creado el campo y añadida la tabla a la
colección «TableDefs», debes de crear la propiedad «Format» en el campo tipo
fecha, para indicarle el formato de fecha corta. Te dejo un ejemplo:

Dim db As Database
Dim tbl As TableDef
Dim fld As DAO.Field
Dim prp As Property

' Abrimos la base de datos
Set db = OpenDatabase("C:\Mis documentos\Base1.mdb")

' Creamos un nuevo objeto TableDef
Set tbl = db.CreateTableDef("MiTabla")

' Añadimos los campos
With tbl
.Fields.Append .CreateField("CampoEnteroLargo", dbLong)
.Fields.Append .CreateField("CampoFecha", dbDate)
End With

' Añadimos la tabla a la colección TableDefs
db.TableDefs.Append tbl

' Creamos la propiedad «Format»
Set fld = tbl.Fields("CampoFecha")
Set prp = fld.CreateProperty("Format", dbText, "Short Date")

' Añadimos la propiedad a la colección «Properties»
fld.Properties.Append prp

' Cerramos la base de datos
db.Close

Eso es todo.

Un saludo.

Enrique Martínez
[MS MVP - VB]