formato passwd en inputbox

hola Mauricio

1. como hacer para que lo que se escriba en un inputbox sea en formato
contraseña

supongo que por 'formato contraseña' te refieres a los tipicos
caracteres que ocultan(sustituyen visualmete) las contraseñas segun se
escriben. Si es asi y segun creo, en los inputbox no es posible, pero
puedes cambiarlo por un sencillo formulario con un textbox y
asignandole en la propiedad PasswordChar el caracter que deseas sea el
mostrado

2.tengo mi barra de heramientas personalizada y solo quiero que aparezca esa
como menú tengo desabilitadas las otras barras con código al abrir el
libro ...sin embargo el menú predeterminado de excel siempre aparece
gracias por su atencion

aunque hace tiempo que no trabajo con barras, me da la impresion de
que la que llamas barra de herramientas no es una barra de menu
propiamente dicha. Segun creo, excel no permite ocultar 'todas' las
barras de menu, en caso de no tener una (valida) personalizada para
sustituirlas, siempre va a mostrar una barra de menus (bien la de hoja
de calculo, bien la de graficos)

pero si no recuerdo mal si puedes ocultarla si la que la sustituye es
una barra valida de menu, no de herramientas

de todas formas ahora mismo no tengo muy fresco el tema, pero creo que
debes mostrar explicitmente la tuya previa habilitacion (Ennabled
=true y Visible = true) y ocultar la principal

espero alguien sea mas concreto y en cualquier caso no estaria de mas
que expusieras como creas la barra y como la muestras y ocultas (el
codigo)

un saludo
Ivan

Ivan gracias,
1. para esta voy a tomar en cuenta tu propuesta
2. las barras las oculto individualmente al abrir el libro así:
Application.CommandBars("standard").Visible = False
luego al cerrar el libro las pongo de nuevo visibles
Application.CommandBars("standard").Visible = True
a. No hallé la manera de crear un menú personalizado para reemplazar el
predeterminado de excel
b. hay modo de ocultar y poner visibles todas las barras de herramientas con
un solo comando para evitar hacerlo una por una ?
Gracias
"Ivan" wrote:

hola Mauricio

> 1. como hacer para que lo que se escriba en un inputbox sea en formato
> contraseña

supongo que por 'formato contraseña' te refieres a los tipicos
caracteres que ocultan(sustituyen visualmete) las contraseñas segun se
escriben. Si es asi y segun creo, en los inputbox no es posible, pero
puedes cambiarlo por un sencillo formulario con un textbox y
asignandole en la propiedad PasswordChar el caracter que deseas sea el
mostrado

> 2.tengo mi barra de heramientas personalizada y solo quiero que aparezca esa
> como menú tengo desabilitadas las otras barras con código al abrir el
> libro ...sin embargo el menú predeterminado de excel siempre aparece
> gracias por su atencion


aunque hace tiempo que no trabajo con barras, me da la impresion de
que la que llamas barra de herramientas no es una barra de menu
propiamente dicha. Segun creo, excel no permite ocultar 'todas' las
barras de menu, en caso de no tener una (valida) personalizada para
sustituirlas, siempre va a mostrar una barra de menus (bien la de hoja
de calculo, bien la de graficos)

pero si no recuerdo mal si puedes ocultarla si la que la sustituye es
una barra valida de menu, no de herramientas

de todas formas ahora mismo no tengo muy fresco el tema, pero creo que
debes mostrar explicitmente la tuya previa habilitacion (Ennabled
=true y Visible = true) y ocultar la principal

espero alguien sea mas concreto y en cualquier caso no estaria de mas
que expusieras como creas la barra y como la muestras y ocultas (el
codigo)

un saludo
Ivan

hola Mauricio

2. las barras las oculto individualmente al abrir el libro así:

Application.CommandBars("standard").Visible = False
a. No hallé la manera de crear un menú personalizado para reemplazar el
    predeterminado de excel
b. hay modo de ocultar y poner visibles todas las barras de herramientas con
un solo comando para evitar hacerlo una por una ?<<<<

lo 1º disculpa pues en mi anterior mensaje creo que no estube muy
atinado con las barras

en realidad, para mostrar/ocultar tu barra de menu personalixzada (la
principal que ba debalo del titulo de la aplicacion), debes pej. al
crearla asignarle true a su paramentro menubar, y desde entonces al
mostrarla u ocultarla con Visible automaticamente te mostarar u
ocultara la integrada, pues solo puede estar una visible



si quieres prueba estos codigos, pegandolos en un modulo 'normal' (en
el editor de vba => menu insertar => modulo (a secas o normal,
standard, etc)

luego llama a la macro CrearMiMenu desde la hoja y prueba allamar
tambien a las otras macros

'''**********pega desde aqui

Sub CrearMiMenu()
Dim MiBarraMenu As CommandBar
Dim MiMenu As CommandBarControl
Dim MiElementoDeMenu As CommandBarControl
' eliminamos el menu por si ya estubiera creado
EliminarMiMenu
' añadimos la barra de menu
Set MiBarraMenu = CommandBars.Add(MenuBar:=True)
With MiBarraMenu
.Name = "MiBarraMenu" ' la damos nombre
.Visible = True ' al mostrarla se oculta la de excel
' pues solo puede haber una visible

' a partir de aqui vamos añadiendo los sucesivos menues y
' y sus correspondientes elementos
Set MiMenu = MiBarraMenu.Controls.Add(Type:=msoControlPopup)
With MiMenu
.Caption = "Mi&Archivo"
Set MiElementoDeMenu = .Controls.Add(Type:=msoControlButton)
With MiElementoDeMenu
.Caption = "&MiElemento_1"
.OnAction = "MiMacro"
End With
Set MiElementoDeMenu = .Controls.Add(Type:=msoControlButton)
With MiElementoDeMenu
.Caption = "MiEleme&nto_2"
.OnAction = "MiMacro"
End With
Set MiElementoDeMenu = .Controls.Add(Type:=msoControlButton)
With MiElementoDeMenu
.Caption = "MiElement&o_3"
.OnAction = "MiMacro"
End With
End With
Set MiMenu = MiBarraMenu.Controls.Add(Type:=msoControlPopup)
With MiMenu
.Caption = "Mi&Edicion"
Set MiElementoDeMenu = .Controls.Add(Type:=msoControlButton)
With MiElementoDeMenu
.Caption = "&MiElemento_1"
.OnAction = "MiMacro"
End With
Set MiElementoDeMenu = .Controls.Add(Type:=msoControlButton)
With MiElementoDeMenu
.Caption = "MiEleme&nto_2"
.OnAction = "MiMacro"
End With
Set MiElementoDeMenu = .Controls.Add(Type:=msoControlButton)
With MiElementoDeMenu
.Caption = "MiElemen&to_3"
.OnAction = "MiMacro"
End With
End With
End With
End Sub
'--
Sub EliminarMiMenu()
On Error Resume Next
CommandBars("MiBarraMenu").Delete
On Error GoTo 0
End Sub
'-
Sub MostrarMiMenu()
On Error Resume Next
CommandBars("MiBarraMenu").Visible = True
If Err.Number <> 0 Then CrearMiMenu
On Error GoTo 0
End Sub
'-
Sub OcultarMiMenu()
On Error Resume Next
CommandBars("MiBarraMenu").Visible = False
On Error GoTo 0
End Sub
'
Sub MiMacro()
MsgBox "Este comando esta en construccion"
End Sub


'''*********pega hasta aqui


espro te ayude (voy con prisa pero si quieres comentas)

un saludo
Ivan

hola de nuevo, Mauricio

en cuanto a esta parte =>

..> b. hay modo de ocultar y poner visibles todas las barras de herramientas con

un solo comando para evitar hacerlo una por una ?<<<< <<<

si vas a andar cambiando/alterando la interface del usuario, lo 1º que
[creo] deberias tener en cuenta, sobre todo si el codigo va correr en
maquinas ajenas, es que al salir de tu aplicacion, el usuario esperara
encontrarse sus ventanas tal y como estaban cuando entro a ella

para ello una posibilidad es almacenar en algun sitio (una matriz, una
hoja, ) el estado (al menos) en que se encontraban los elementos
que pienses manipular antes de actuar sobre ellos

en estas macros se utiliza una hoja llamad "Oculta" y que como su
nombre indica la puedes ocultar (evidentemente tras crearla) para
almacenar el estado de las barras integradas de excel y ocultarlas
(mostrando las tuyas) o mostrarlas (ocultando las tuyas)

pegalo en el mismo modulo que hayas pegado los codigos anteriores, a
continuacion de estos y haz unas pruebas ( en este ej. si quieres que
actue tambien sobre tus otras barras ,deberias incluir, dentro de los
procedimientos "CrearMiMenu,MostrarMiMenu, etc la instruccion
correspondiente a esas barras => TuBarraTal.Visible = SegunMacro )

''**********************************
'--pone en una hoja ("Oculta") en la colA una lista con
' los nombres de todas las barras integradas (excepto las
' 2 de menus [Hoja y Graficos]) y carga en la columna B su
' estado visible
'
Sub OcultarBarras()
Dim cmb As CommandBar, n As Integer
With Worksheets("Oculta")
n = 1: .[a:b].Clear
MostrarMiMenu
For Each cmb In CommandBars
If cmb.BuiltIn And cmb.Name <> "Worksheet Menu Bar" _
And cmb.Name <> "Chart Menu Bar" Then
.Cells(n, 1) = cmb.Name
.Cells(n, 2) = cmb.Visible
If cmb.Visible Then cmb.Visible = False
n = n + 1
End If
Next
End With
End Sub
'--recupera el estado de visibilidad de las barras
' segun lo cargado en la hoja Oculta
'
Sub MostrarBarras()
Dim cmb As CommandBar, n As Integer
n = 1
OcultarMiMenu
With Worksheets("Oculta")
For n = 1 To .Cells(65536, 1).End(xlUp).Row
If CommandBars(.Cells(n, 1).Value).Visible <> _
.Cells(n, 2) Then CommandBars(.Cells(n, 1).Value) _
.Visible = .Cells(n, 2)
Next
End With
End Sub
'''- otra posibilidad recorriendo solo las visibles
'
Sub OcultarVisibles()
Dim cmb As CommandBar, n As Integer
n = 1: Worksheets("Oculta").[a:b].Clear
CrearMiMenu
For Each cmb In CommandBars
If cmb.Name <> "Worksheet Menu Bar" _
And cmb.Name <> "Chart Menu Bar" And _
cmb.BuiltIn And cmb.Visible Then
Worksheets("Oculta").Cells(n, 1) = cmb.Name
cmb.Visible = False
n = n + 1
End If
Next
End Sub
'-
Sub MostrarVisibles()
Dim cmb As CommandBar, n As Integer
n = 1
OcultarMiMenu
With Worksheets("Oculta")
For n = 1 To .Cells(65536, 1).End(xlUp).Row
CommandBars(.Cells(n, 1).Value).Visible = True
Next
End With
End Sub
'''********************************

una cosa +/- conveniente es por ej. incluir el ocultar el
mostrar7ocultar las barras en el /los eventos del libro Activate/
Deactivate y/o WindowActivate/WndowDeactivate

aparte, aunque durante la ejecucion podrias mantenerlas ocultas cuando
no este en tu aplicacion el usuario, teniendo cuidado de ocultarlas en
el menu ver => Barras de herramientas (creo que tendrias que modificar
el enabled para ello, pero no estoy seguro, me acabo de acordar y no
lo he comprobado), al cerrar tu archivo convendria que las eliminaras,
volviendo a crearlas al abrir

para ello tendrias los eventos Open y BeforeClose (con este ojo, pues
si se cancela el cierre en el mensaje de guardar los cambios volverias
al archivbo pero tus barras ya habrian sido eliminadas si es que no lo
has previsto)

bueno disculpa los rollos y si quieres comentas com te va

un saludo
ivan