ado Principiante

"Martin Cabrera" preguntó:

como conecto un datagrid con codigo a una base de datos
accses ado

Hola, Martín:

Si trabajas con Visual Basic, aquí tienes un ejemplo comentado:

Private Sub Form_Load()

' Declaración de variables objeto
Dim cnn As ADODB.Connection
Dim rs As ADODB.Recordset

' Creamos un nuevo objeto «Connection»
Set cnn = New ADODB.Connection

' Configuramos la conexión
With cnn
.Provider = "Microsoft.Jet.OLEDB.4.0"
.ConnectionString = "Data Source=C:\Mis documentos\Bd1.mdb"
' Abrimos la base de datos
.Open
End With

' Creamos un nuevo objeto «Recordset»
Set rs = New ADODB.Recordset

' Configuramos el objeto «Recordset»
With rs
' Utilizamos cursores del lado cliente para que
' se rellene el control «DataGrid»
.CursorLocation = adUseClient

' Establecemos el tipo de cursor
.CursorType = adOpenStatic

' El tipo de bloqueo
.LockType = adLockOptimistic

' Abrimos la tabla «Saldo» de la base de datos
.Open "Saldo", cnn, , , adCmdTable
End With

' Propiedades del control «DataGrid»
With DataGrid1
' Permitimos añadir y eliminar registros
.AllowAddNew = True
.AllowDelete = True

' Enlazamos el control «DataGrid» con el objeto
' «Recordset»
Set .DataSource = rs
End With

End Sub

como hago para que no me de error cuando ingreso texto en
una casilla ( text1 ) que esta conectada a la base de
datos en la tabla saldo (numeros)

Pues como no sé lo que estás haciendo, ignoro el motivo del error. La manera
de enlazar un control «TextBox» a un objeto «Recordset» ,en tiempo de
ejecución, es la siguiente:

' Configuramos el cuadro de Texto, enlazando
' el control al objeto «Recordset»
Set Text1.DataSource = rs

' Indicamos el campo de la tabla
Text1.DataField = "Numeros"

En principio te debería permitir ingresar texto sin obtener ningún tipo de
error.

Un saludo.

Enrique Martínez
[MS MVP - VB]