macro: pegar filas en otra hoja a continuacion de filas existente

Hola Christian,

Suponiendo que quieres copiar la primera fila de la hoja activa a la primera
fila debajo de la ultima fila con datos de la segunda hoja del libro...

1) Si no usas formatos en la hoja (ademas de los que estan por defecto) o si
se podria decir que los formatos nuevos acaban con la ultima celda con
datos, entonces podrias usar algo asi:

Sub CopiarFilas1()
With Sheets(2)
.UsedRange
ActiveSheet.Rows(1).Copy _
.Cells.SpecialCells(xlCellTypeLastCell). _
Offset(1, 0).EntireRow
End With
End Sub

2) Si la condicion de arriba no se cumple...

a. una opcion podria ser la de identificar una columna donde debe aparecer
el ultimo dato, p.ej la columna [A], y entonces usar:

Sub CopiarFilas2()
With Sheets(2)
ActiveSheet.Rows(1).Copy _
.Cells(.Rows.Count, "A").End(xlUp).Offset(1, 0).EntireRow
End With
End Sub

b. o tambien podrias hacer esto:

Sub CopiarFilas3()
Dim fila As Range
With Sheets(2)
Set fila = .Cells.Find("*", .Cells(1), _
xlValues, xlWhole, xlByRows, xlPrevious) _
.Offset(1, 0).EntireRow
End With
ActiveSheet.Rows(1).Copy fila
End Sub

Saludos,
KL




"christian k" <christian wrote in message
news:

necesito macro o funcion que pegue filas en otra hoja especifica
inmediatamente abajo de la ultima celda ocupada.