Macros

Automatizar el Guardar en dos carpetas distintas, sería un respaldo del documento.


***************************
Option Explicit

Dim WithEvents o As Word.Application

Dim PorCodigo As Boolean 'Variable para controlar si es nuestro código el que graba





Private Sub Document_Close()

Set o = Nothing

End Sub



Private Sub Document_Open()

Set o = Application

End Sub



Private Sub o_DocumentBeforeSave(ByVal Doc As Document, SaveAsUI As Boolean, Cancel As
Boolean)

Dim NombreDocumento As String 'Variable para manejar el nombre del Documento

Dim PrimerCarpeta As String 'Variable para manejar la primer carpeta

Dim SegundaCarpeta As String 'idem para la segunda

PrimerCarpeta = "C:\Documents and Settings\Nilda\Mis documentos\"

'en la línea anterior hay que colocar el primer camino para guardar

SegundaCarpeta = "z:\Reserva\"

'en la línea anterior hay que colocar el segundo camino para guardar

If PorCodigo Then 'Si es nuestro código el que graba

Exit Sub 'sale de este procedimiento

'Este procedimiento se ejecuta SIEMPRE antes de grabar

'inclusive cuando se graba por código, como sucede por debajo

'si no colocamos esto el procedimiento se llama a sí mismo infinitas veces

End If

PorCodigo = True 'indicamos que grabamos por nuestro código

NombreDocumento = Doc.Name 'obtenemos el nombre del Documento

If Left$(NombreDocumento, 9) = "Documento" Then 'si el nombre del Documento empieza con
Documento

NombreDocumento = InputBox("Ingrese el nombre del Documento") 'Pide el nuevo nombre

End If

'La siguiente línea, que está desactivada, evita que muestre el mensaje de que ya exixte

'el archivo, si se quiere sobreescribir

'Para activarla solo sacar el apóstrofo inicial

'Application.DisplayAlerts = False

Doc.SaveAs PrimerCarpeta & NombreDocumento 'Graba con el nombre en la primera

Doc.SaveAs SegundaCarpeta & NombreDocumento 'Graba con el nombre en la segunda

PorCodigo = False 'indicamos que ya no grabamos por código

Cancel = True 'devuelve a Word que ya no tiene que grabar

End Sub


Suerte
Nilda Beatriz Díaz
MS - MVP
Desde el tercer planeta a partir del Sol
"Compumakro" escribió en el mensaje
news:

Amigos
Yo le veo función a las Macros en Excel, pero no se me ocurre una Macro para
Word.
Alguien me puede obsequiar un archivo de Word con una Macro sencilla y de un
empleo lógico para una oficina, solo para ver como se hace y como funciona.

Gracias
Oscar
Barranquilla