Crear carpetas

Aprendiz,

Prueba el macro de abajo.

Saludos,
KL

'Inicio Codigo-
Sub AgregarHojaNueva()
Dim carInvalidos As Variant
Dim Celda As Range
Dim Hoja As Worksheet
Dim i As Integer
Dim NombreUnico As Boolean
Dim NombreValido As Boolean
Dim Ant As Integer
Dim Desp As Integer

carInvalidos = Array(":", "\", "/", "?", "*", "[", "]")

Application.ScreenUpdating = False
With ThisWorkbook
For Each Celda In Worksheets("Carpetas archivo").Range("A1:A10")

'comprobamos si ya existen hojas con los
'nombres q queremos usar.
NombreUnico = True
For Each Hoja In Worksheets
If Hoja.Name = Celda Then
MsgBox "Ya existe una hoja con el nombre: " _
& Celda
NombreUnico = False
Exit For
End If
Next Hoja

'comprobamos si el nombre contiene
'caracteres invalidos.
NombreValido = True
For i = 0 To UBound(carInvalidos)
If InStr(Celda, carInvalidos(i)) Then
MsgBox "El nombre " & Celda _
& " contiene caracteres invalidos."
NombreValido = False
Exit For
End If
Next i

'Creamos las hojas y asignamos los nombres validos.
If Not IsEmpty(Celda) And NombreUnico And NombreValido Then
Worksheets.Add(After:= _
Worksheets(Worksheets.Count)).Name = Celda.Value
End If
Next Celda

'Procedemos a ordenar las hojas alfabeticamente.
For Desp = 2 To Worksheets.Count
For Ant = Desp To Worksheets.Count
If UCase(Worksheets(Ant).Name) < _
UCase(Worksheets(Desp).Name) Then _
Worksheets(Ant).Move Before:=Worksheets(Desp)
Next
Next

'volvemos a la hoja principal.
Worksheets("Carpetas archivo").Activate
End With
End Sub
'Fin Codigo-


"Aprendiz" wrote in message
news:
> Saludos KL
> Te agradezco los links, pero están en inglés y todavía estoy un poco

> para entender código.
> Te pediría que para ayudarme, me escribieras un código para realizar lo
> siguiente:
> En un libro "Archivo general", la primera hoja se llama "Carpetas
> archivo",
> y en la celda A1 y sucesivas A2, A3, etc.. estoy escribiendo el nombre

> las siguientes hojas del libro solo necesito escribir en las

> (hojas del libro) que todavia no se han creado, dichos nombres mediante
> código VBA. Gracias
> José Rafael
> "KL" <lapink2000(at)hotmail.com> escribió en el mensaje
> news:
>> Aprendiz,
>>
>> Para ejemplos de codigo podrias consultar estos links (mirate bien el
>> hilo
>> entero)
>>
>> Saludos,
>> KL
>>
>>
>

>>
>>
>

>>
>>
>

>>
>>
>> "Aprendiz" wrote in message
>> news:
>> > De todas maneras necesito una base de código para sobre ella
>> > modificarlo
>> > hasta conseguir lo que necesito, que no sé explicarlo mejor. Para mí

>> > mas
>> > facil si tengo ese código básico que simplemente ponga nombre a
>> > pestañas
>> > de
>> > un libro. Gracias de todos modos.
>> > José Rafael
>> >
>> > "Héctor Miguel" escribió en el

>> > news:
>> >> hola, José Rafael !
>> >>
>> >> > ... codigo para crear carpetas en un directorio a elegir ???...
>> >> > ... cuyos nombres de carpetas (¿máximo nº de letras?) corresponden
>> >> > al
>> > rango A1:A100 [...]
>> >>
>> >> 1.- revisa en la ayuda de vba acerca de las instrucciones: MkDir,
> RmDir,
>> > Kill
>> >> 2.- toma las debidas precauciones para que los nombres NO contengan
>> > caracteres 'no validos'
>> >> 3.- habra que 'validar' si algunos directorios 'ya existieran'
>> >> [suponiendo
>> > que el codigo sea 'repetible']
>> >> 4.- revisa el siguiente enlace: http://tinyurl.com/5ords
>> >>
>> >> si cualquier duda o informacion adicional... ¿comentas?
>> >> saludos,
>> >> hector.
>> >>
>> >>
>> >
>> >
>>
>>
>
>

...te puedo decir que aprendo muchos de todas tus respuestas
incluída ésta.

Felices fiestas.