multiplicar digitos y sumar

Con el permiso que me da el silencio de botellas trataré de contestar a tu
pregunta:
Para ello partamos de otra solución un poquito mas larga, pero más visible
"su funcionamiento".
Para centrarnos en el proceso, supongamos que el resultado de la
multiplicación de A2,A3,... lo recogemos en la celda A1


"julian-Vlc-Sp" escribió en el
mensaje de noticias
news:

¿Podrás explicar la logica de la expresion que propones?

GRACIAS


SALUDOS.
julian-Valencia-España

http://ijulian.iespana.es
http://www.tinyurl.com/julianvalencia



"sailepaty" wrote:

Una opción con formula,

=SUMAPRODUCTO(LARGO(SUSTITUIR(A2*A3;{1\2\3\4\5\6\7\8\9\""};""))*-{1\2\3\4\5\6\7\8\9\-45})

Saludos

Con el permiso que me da el silencio de botellas trataré de contestar a tu
pregunta:
Para ello partamos de otra solución un poquito mas larga, pero más visible
"su funcionamiento".
Para centrarnos en el proceso, supongamos que el resultado de la
multiplicación de A2,A3,... lo recogemos en la celda A1


=SUMAPRODUCTO(LARGO(A1)-LARGO(SUSTITUIR(A1;{1\2\3\4\5\6\7\8\9};""));{1\2\3\4\5\6\7\8\9})

La función LARGO combinada con la de SUSTITUIR nos "cuenta" las veces que en
A1 están cada uno de los 9 dígitos de nuestro sistema decimal (el cero no lo
buscamos
pues en este caso "no suma").
La función SUMAPRODUCTO lo multiplica por cada dígito, arrojando como
resultado el dato que buscamos.

La solución propuesta por botellas saca factor común sustituyendo a
LARGO(A1) por SUSTITUIR(A1;"";"")
y {1\2\3\4\5\6\7\8\9} por su suma 45; el cambio de signo en el segundo
multiplicando de la opción de botellas y en el 45 es consecuencia lógica de
sacar factor común.

No sé si he logrado explicarme, pero esa era mi intención.
Saludos.-

"julian-Vlc-Sp" escribió en el
mensaje de noticias
news:

¿Podrás explicar la logica de la expresion que propones?

GRACIAS


SALUDOS.
julian-Valencia-España

http://ijulian.iespana.es
http://www.tinyurl.com/julianvalencia



"sailepaty" wrote:

Una opción con formula,

=SUMAPRODUCTO(LARGO(SUSTITUIR(A2*A3;{1\2\3\4\5\6\7\8\9\""};""))*-{1\2\3\4\5\6\7\8\9\-45})

Saludos

Gracias por la atencion prestada, pero he leido varias veces tu respuesta y
soy incapaz de entender el funcionamiento.

Debe ser cosa de la edad


SALUDOS.
julian-Valencia-España

http://ijulian.iespana.es
http://www.tinyurl.com/julianvalencia



"sailepaty" wrote:

>>
"julian-Vlc-Sp" wrote:
¿Podrás explicar la logica de la expresion que propones?
GRACIAS
> >

Digamos que en la celda A2 tienes el valor 16 y deseamos sumar los dígitos,
entonces la formula inicialmente es:

=SUMAPRODUCTO(LARGO(SUSTITUIR(A2;{1\2\3\4\5\6\7\8\9\""};""))*-{1\2\3\4\5\6\7\8\9\-45})

La 1ª. parte sustituye cada valor encontrado por nada o dobles comillas. Ojo
con el último elemento sustituido que era “” por “” por lo cual regresa el
valor original de A2.

=SUMAPRODUCTO(LARGO({"6"\"16"\"16"\"16"\"16"\"1"\"16"\"16"\"16"\"16"})*-{1\2\3\4\5\6\7\8\9\-45})

La 2ª. parte obtiene el largo de cada uno de los elementos después de la
sustitución.

=SUMAPRODUCTO({1\2\2\2\2\1\2\2\2\2}*-{1\2\3\4\5\6\7\8\9\-45})


La 3ª. parte multiplica el largo de cada elemento por los valores de cada
digito del 1 al 9. El último elemento que es igual al largo total del valor
en A2 se multiplica por 45 porque ese es el resultado de sumar
1+2+3+4+5+6+7+8+9

=SUMAPRODUCTO({-1\-4\-6\-8\-10\-6\-14\-16\-18\90})

Por lo tanto -1 + -4 + -6 + -8 + -10 +-6 + -14 + -16 + 90 = 7

Espero haber aclaro algo y no haberlo enredado mas.

Saludos