Nombres antiguos

hola, Des !

> Si puedes facilitar ayuda sobre:
> -Contar ficheros en un directorio y abrirlo secuencialmente
> -ver añadir o quitar a las cadenas caracteres ASCII , no letras
> -Sacar la fecha y el tamaño del nombre de un fichero

el siguiente mensaje es un pelin largo (asi que te armas de paciencia, ok ?)
y si cualquier duda (o informacion adicional)... comentas ?
saludos,
hector.

-Contar ficheros en un directorio y abrirlo secuencialmente

1) si los vas a abrir... no se cual seria la intencion de "contarlos" (?)

- contarlos (de la forma mas sencilla que se me ocurre)

Sub Cuenta_archivos()
Dim Directorio As String, Tipo As String, Fichero As String
Directorio = "c:\mis documentos\"
Tipo = "*.xls"
MsgBox ExecuteExcel4Macro("counta(files(""" & Directorio & Tipo & """))")
End Sub

- abrirlos (uno por uno, los "trabajas", y LOS CIERRAS)

Sub Abrir_archivos_en()
Dim Directorio As String, Tipo As String, Fichero As String
Directorio = "c:\mis documentos\" ' <= AJUSTA
Tipo = "*.xls"
Archivo = Dir(Directorio & Tipo)
Do While Archivo <> ""
Workbooks.Open Ruta & Archivo
' aqui "trabajas con cada archivo Y LO CIERRAS... '
Workbooks(Archivo).Close SaveChanges:=False ' o True ??? '
Archivo = Dir()
Loop
End Sub

-ver anadir o quitar a las cadenas caracteres ASCII , no letras

2) para esta parte, una posible solucion (sencilla) pudiera ser el uso de expresiones regulares
dependiendo de como necesites "validar" algunos otros caracteres (espacios, guiones, puntos,

por si puedes apuntar algunos detalles mas concretos ?

-Sacar la fecha y el tamano del nombre de un fichero

3) prueba con una macro +/- como la siguiente (en un directorio de pocos archivos)

Sub Muestra_fechas_y_tamano()
Application.ScreenUpdating = False
Dim Msj As String, Ruta As String, Tipo As String, Archivo As String, _
Last As String, Fecha As Date, Hora As Date, Tamano As String
Msj = "Modificado (fecha y hora):" & vbTab & "Tamaño (Kb):" & vbTab & "Nombre archivo:"
Ruta = "c:\mis documentos\" ' <= AJUSTA
Tipo = "*.xls"
Archivo = Dir(Ruta & Tipo)
Do While Archivo <> ""
Last = FileDateTime(Ruta & Archivo)
Fecha = Left(Last, InStr(Last, " ") - 1)
Hora = Mid(Last, InStr(Last, " ") + 1)
Tamano = Format(FileLen(Ruta & Archivo) / 1024, "#,##0.0") & " Kb"
Msj = Msj & vbCr & Fecha & vbTab & Hora & vbTab & Tamano & vbTab & Archivo
Archivo = Dir()
Loop
MsgBox Msj
End Sub

esta es otra forma de obtener diversos atributos de los archivos en una carpeta:
(que puedes adaptar para otras necesidades)...
1) toma la carpeta predeterminada que pongas en 'A1' (p.e. -> c:uta y\sub-carpeta)
2) pone en el rango 'A2:E2' los titulos para algunos de los atributos de los archivos
3) a partir de la fila 3, vacia los nombres de los archivos que se encuentren (y sus atributos)

Sub LIsta_de_archivos()
Application.ScreenUpdating = False
Dim Carpeta As String: Carpeta = Range("a1"): Cells.Clear
Range("a2:e2") = Array("Ruta", "Nombre", "Tamaño", "Modificado", "Tipo")
Listar_archivos_en Carpeta, True
End Sub

Sub Listar_archivos_en(Carpeta As String, Completo As Boolean)
Dim Archivo, SubCarpeta, Fila As Long
Fila = Range("a65536").End(xlUp).Row + 1
With CreateObject("scripting.filesystemobject")
With .GetFolder(Carpeta)
For Each Archivo In .Files
With Archivo
Range("a" & Fila & ":e" & Fila) = Array( _
Application.Substitute(.Path, .Name, ""), .Name, .Size, .DateLastModified, .Type)
End With
Fila = Fila + 1
Next
If Completo Then
For Each SubCarpeta In .SubFolders
Listar_archivos_en SubCarpeta.Path, True
Next
End If
End With
End With
Range("a1:e1").EntireColumn.AutoFit
Range("a1") = Carpeta
Debug.Print ActiveSheet.UsedRange.Address
End Sub