Ayuda por favor

hola, Francisco !

... este problema que me trae de cabeza
... la serie de valores 4,5,4,6,5,3,3,1 situados ... en las celdas A1, B1,... G1, H1
... valor mas repetido usando la formula MODA(A 1: H 1) nos devuelve el n° 4
... veces que ... esta repetido ... la formula CONTAR.SI(A1:H1);MODA(A1:H1) es ... 2 veces
¿... formula que devuelva el mayor numero ... repetido igual de veces que el que devuelve ... MODA
... en este caso seria el numero 5
... y ... formula que devolviese el valor menor en este caso el numero 3 ?

antes... un comentario [que considero] 'importante' con relacion a la funcion 'moda'...
-> para el caso que planteas de numeros con las mismas n_repeticiones... la funcion moda()...
NO te devuelve el numero con 'el mayor' numero de 'repeticiones' sino...
te devuelve ->el primer numero<- [en la serie] con el mayor numero de repeticiones
[si 'inviertes' el inicio de 4,5 a 5,4... 'te dira' que es el 5]

te expongo dos formulas ->matriciales<- [ya sabes... al introducir/editar 'terminar' con ctrl+may+anter]
-> es necesario 'ampliar' el rango una celda mas [una celda 'tonta' y ->vacia<-] de 'A1:H1' a 'A1:I1' <= OJO

la formula para devolver el numero mayor con n_repeticiones ['compartidas' o no] es...
_____
=max(transponer(a1:i1)*(frecuencia(a1:h1;a1:h1)=max(frecuencia(a1:h1;a1:h1))))

la formula para devolver el numero menor con n_repeticiones ['compartidas' o no]
-> que no fue 'tan corta' [como seria 'deseable'] puesto que requiere 'eliminar' los ceros en una funcion 'min()'
y 'toma nota' de que ->debe 'quedar' en una sola linea<- es...
_____
=min(si(transponer(a1:i1)>0;transponer(a1:i1);max(a1:h1))
*si(frecuencia(a1:h1;a1:h1)=0;max(a1:h1)
;si(frecuencia(a1:h1;a1:h1)<max(frecuencia(a1:h1;a1:h1));max(a1:h1)
;frecuencia(a1:h1;a1:h1)=max(frecuencia(a1:h1;a1:h1)))))

en ambas formulas, si los datos estuvieran en una sola columna, se podria 'prescindir' de la funcion 'transponer()' ;)
saludos,
hector.

p.d. en un 'chance' buscare la manera de 'adelgazarlas' [sobre todo a la segunda]
[a menos que se me adelante alguien en el grupo]

Otras dos posibilidades, sólo por no "dejarlas nonatas":

=MAX((CONTAR.SI(A1:H1;A1:H1)=CONTAR.SI(A1:H1;MODA(A1:H1)))*A1:H1)

y

=MIN(SI((CONTAR.SI(A1:H1;A1:H1)=CONTAR.SI(A1:H1;MODA(A1:H1)))*A1:H1>0;A1:H1))

Un saludo.


Fernando Arroyo
MS MVP - Excel


"Francisco Sanchez" escribió en el mensaje news:

Hola

Me podriais echar una mano con este problema que me trae de cabeza

Dada la serie de valores 4,5,4,6,5,3,3,1 situados respectivamente en las
celdas A1, B1,... G1, H1



El valor mas repetido usando la formula MODA(A 1: H 1) nos devuelve el n° 4

El numero de veces que el valor esta repetido mediante la formula
CONTAR.SI«A1:H1);MODA(A1:H1» es igual a 2 veces



Hasta aquí todo bien, pero mi pregunta es la siguiente:

¿Hay alguna formula que devuelva el mayor numero que este repetido igual de
veces que el que devuelve la función MODA que en este caso seria el numero
5, y puestos a pedir una formula que devolviese el valor menor en este caso
el numero 3 ?



Gracias anticipadas

Fernando Arroyo escribio en el mensaje
Otras dos posibilidades, solo por no "dejarlas nonatas":
=MAX((CONTAR.SI(A1:H1;A1:H1)=CONTAR.SI(A1:H1;MODA(A1:H1)))*A1:H1)
y
=MIN(SI((CONTAR.SI(A1:H1;A1:H1)=CONTAR.SI(A1:H1;MODA(A1:H1)))*A1:H1>0;A1:H1))

mas 'delgadas'... 'universales'... y 'transparentes'. 'simplemente'... ¡ excel...entes !!!

saludos,
hector.

p.d. no hay que 'dejar nada... en el tintero' ;)

"Héctor Miguel" escribió en el mensaje news:

> Fernando Arroyo escribio en el mensaje
> Otras dos posibilidades, solo por no "dejarlas nonatas":
> =MAX((CONTAR.SI(A1:H1;A1:H1)=CONTAR.SI(A1:H1;MODA(A1:H1)))*A1:H1)
> y
> =MIN(SI((CONTAR.SI(A1:H1;A1:H1)=CONTAR.SI(A1:H1;MODA(A1:H1)))*A1:H1>0;A1:H1))

mas 'delgadas'... 'universales'... y 'transparentes'. 'simplemente'... ¡ excel...entes !!!

saludos,
hector.

p.d. no hay que 'dejar nada... en el tintero' ;)

Gracias. Es un comentario muy amable, especialmente viniendo de alguien de quien todos aprendemos tanto.
Un saludo.


Fernando