cargar datos en listbox userform desde una matriz trabajando con vba excel97

Hola vdadesolano,

1) comentarte que el codigo que expones (tal cual) lo realizaria de una de las siguientes formas (es mas eficiente pasar el rango a
matriz directamente que usar bucle)

'Inicio Codigo 1
Sub ABRIR1()
' si NO hay formatos fuera del area de datos
Dim Matriz As Variant, oLibro As Workbook, y As Long
ArchivoAAbrir = Application.GetOpenFilename _
("Archivos de Microsoft Excel (*.XLS), *.XLS")
If ArchivoAAbrir <> False Then
Set oLibro = Workbooks.Open(ArchivoAAbrir)
With oLibro
With .Worksheets("Hoja1").UsedRange
y = .Columns.Count
Matriz = .Offset(2).Resize(.Rows.Count - 2).Value
End With
.Close
End With
With UserForm1
With .ListBox1
.ColumnCount = y
.List() = Matriz
End With
.Show
End With
End If
End Sub
'Fin Codigo 1

'Inicio Codigo 2
' si hay formatos fuera del area de datos
Sub ABRIR2()
Dim Matriz As Variant, oLibro As Workbook, x As Long, y As Long
ArchivoAAbrir = Application.GetOpenFilename _
("Archivos de Microsoft Excel (*.XLS), *.XLS")
If ArchivoAAbrir <> False Then
Set oLibro = Workbooks.Open(ArchivoAAbrir)
With oLibro
With .Worksheets("Hoja1")
x = .Cells(.Rows.Count, "A").End(xlUp).Row
y = .Cells(3, .Columns.Count).End(xlToLeft).Column
Matriz = .Range(.Range("A3"), .Cells(x, y)).Value
End With
.Close
End With
With UserForm1
With .ListBox1
.ColumnCount = y
.List() = Matriz
End With
.Show
End With
End If
End Sub
'Fin Codigo 2

2) Si solo necesitas meter en un listbox los valores unicos de UNA columna (digamos la columna [A]) podrias usar el siguiente
codigo:

'Inicio Codigo 3
Sub ABRIR3()
Dim Matriz As Variant, oLibro As Workbook, x As Long, y As Long
ArchivoAAbrir = Application.GetOpenFilename _
("Archivos de Microsoft Excel (*.XLS), *.XLS")
If ArchivoAAbrir <> False Then
Set oLibro = Workbooks.Open(ArchivoAAbrir)
With oLibro
With .Worksheets("Hoja1")
Matriz = Unique(.Range(.Range("A3"), _
.Cells(.Rows.Count, "A").End(xlUp)))
End With
.Close
End With
With UserForm1
.ListBox1.List() = Matriz
.Show
End With
End If
End Sub

Function Unique(inArray As Range) As Variant
Dim colItems As Collection
Dim cell As Range
Dim temp As Variant

Set colItems = New Collection
On Error Resume Next
For Each cell In inArray
colItems.Add cell.Value, CStr(cell.Value)
Next cell
ReDim temp(colItems.Count)
For i = 1 To colItems.Count
temp(i) = colItems.Item(i)
Next i
Unique = temp
End Function
'Fin Codigo 3

3) Si aparte de filtrar valores unicos necesitas que esten ordenados alfabeticamente, podrias usar la siguiente funcion de John
Walkenbach:
http://j-walk.com/ss/excel/tips/tip15.htm

4) Si es otra cosa, comentas detalles adicionales?

Saludos,
KL

Hola de nuevo,

"KL" wrote:

3) Si aparte de filtrar valores unicos necesitas que esten ordenados alfabeticamente, podrias usar la siguiente funcion de John
Walkenbach:
http://j-walk.com/ss/excel/tips/tip15.htm

Parece que me he equivocado de codigo y no consigo encontrar el que tenia en mente. En todo caso, so quieres que te ordene los
datos, puedes sustituir la funcion que te puse antes con la siguiente:

Function Unique(inArray As Range) As Variant
Dim colItems As Collection
Dim cell As Range
Dim temp As Variant

Set colItems = New Collection
On Error Resume Next
For Each cell In inArray
colItems.Add cell.Value, CStr(cell.Value)
Next cell
For i = 1 To colItems.Count - 1
For j = i + 1 To colItems.Count
If colItems(i) > colItems(j) Then
Swap1 = colItems(i)
Swap2 = colItems(j)
colItems.Add Swap1, before:=j
colItems.Add Swap2, before:=i
colItems.Remove i + 1
colItems.Remove j + 1
End If
Next j
Next i
ReDim temp(colItems.Count)
For i = 1 To colItems.Count
temp(i) = colItems.Item(i)
Next i
Unique = temp
End Function

Saludos,
KL

Hola a todos . Abrumado por tanta atencion recibida y agradecido
,muchas gracias KL, acabo de llegar de trabajar y todavia no he cenado.
Pero mañana comenzare a digerir toda la información recibida. Como
estoy algo pez se prevee que la digestion será larga.No dudo que tal y
como me relaciono yo con esta codigo muy pronto acabaré metido en un
nuevo lodazal del que no sabré como salir. Pero creo que en el fondo
es lo que me divierte , no tener ni puñetera idea de por donde voy ni
de en que me he metido.