Cargar elementos de un listbox con un objeto

Hola:
Prueba esto

Crea una clase
Public Class AddItem
Private moClave As Object
Private msNombre As String

Public Sub New(ByVal Nombre As String, ByVal Clave As Object)
msNombre = Nombre
moClave = Clave
End Sub

Public Property Clave() As Object
Get
Return moClave
End Get
Set(ByVal Value As Object)
moClave = Value
End Set
End Property

Public Property Nombre() As String
Get
Return msNombre
End Get
Set(ByVal Value As String)
msNombre = Value
End Set
End Property

Public Overrides Function ToString() As String
Return msNombre
End Function
End Class

Para cargar los datos
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As
System.EventArgs) Handles Button1.Click
Dim conn As New SqlConnection("server=(local);User
Id=sa;Password=;Initial Catalog=Northwind;")
Dim dr As SqlDataReader
Dim cmd As New SqlCommand
Try
conn.Open()
With cmd
.Connection = conn
.CommandType = CommandType.Text
.CommandText = "Select * from Employees"
End With
dr = cmd.ExecuteReader()
While dr.Read
Me.ListBox1.Items.Add(New AddItem(dr("LastName"),
dr("EmployeeID")))
End While
Catch ex As Exception
MessageBox.Show(ex.Message)
Finally
If Not (dr Is Nothing) Then
dr.Close()
End If
If Not (cmd Is Nothing) Then
cmd.Dispose()
End If
If Not (conn Is Nothing) Then
conn.Close()
conn.Dispose()
End If
End Try
End Sub

Para ver el valor
Private Sub ListBox1_SelectedIndexChanged(ByVal sender As Object, ByVal
e As System.EventArgs) Handles ListBox1.SelectedIndexChanged
MsgBox(DirectCast(Me.ListBox1.SelectedItem,
AddItem).Clave.ToString())
End Sub

Espero que te sirva
Un saludo desde Bilbo:
Carlos

"Wabi" escribió en el mensaje
news:
Mostrar la cita

Necesito hacer lo siguiente:

Cargar un listbox con un campo de texto de una tabla que contine ademas
del campo de texto un id. Quiero ademas cargar en la lista de alguna forma
el id correspondiente a cada campo de texto.
Segun tengo entendido tengo que crear un objeto que contega id y campo de
texto y asignarlo a cada elemento de la lista. Ademas indicar que elemento
voy a utilizar para mostrar en la lista. Quiero poder rescatar el id
cuando el usuario seleccion un elemento de la lista.
Necesito una orientacion para hacer esto.
Muchas gracias por la ayuda.