Como puedo hacer promedios en "x" intervalos de filas???

19/07/2007 - 01:40 por Edo | Informe spam
Qusiera saber sialguin me puedria comentar como hacer promedios cada "x"
numero de filas, es decir:

por ejemplo

Celda B1 =PROMEDIO(A1:A5)
Celda B2 =PROMEDIO(A6:A10)
Celda B3 =PROMEDIO(A11:A15)
Celda B4 =PROMEDIO(A16:A20)
...
...
etc.

si alguien me podria ayudar se lo agradeceria.

Preguntas similare

Leer las respuestas

#1 David
19/07/2007 - 02:58 | Informe spam
Hola, Edo.

Primero, considera que yo utilizo la coma por separador. Si las fórmulas
que te doy no funcionan, prueba cambiar las comas por punto y comas.

Supongamos que vas a calcular el promedio en grupos de 5 en 5 celdas, para
la columna A, a partir de la fila 1. Podrías concatenar la dirección del
rango que vas a promediar con la siguiente expresión en la celda B1:

=CONCATENAR("A",1+(FILA(A1)-1)*5,":A",1+(FILA(A1)-1)*5+5-1)

Pruébala en tu hoja, luego la copias y revisas para verificar si es
correcta. El siguiente paso sería utilizar la función Indirecto(...) para
convertira en un rango que la función Promedio te pueda interpretar. La
fórmula en B1 quedaría así:

=PROMEDIO(INDIRECTO(CONCATENAR("A",1+(FILA(A1)-1)*5,":A",1+(FILA(A1)-1)*5+5-1)))

y la copias hasta donde sea necesario.

Ahora hagamos variantes. Si no fuera la columna A, sino la C, sólo tendrías
que cambiar las letras A que están entre comillas:

=PROMEDIO(INDIRECTO(CONCATENAR("C",1+(FILA(A1)-1)*5,":C",1+(FILA(A1)-1)*5+5-1)))

Observa que no es necesario cambiar la dirección de celda A1. Ésta es solo
referencia, y no te afectaría.

Ahora pensemos en la columna C, pero en grupos de 6. En este caso cambia
todos los 5 por 6:

=PROMEDIO(INDIRECTO(CONCATENAR("C",1+(FILA(A1)-1)*6,":C",1+(FILA(A1)-1)*6+6-1)))

Por último, pensemos en iniciar en la fila 3, en lugar de la fila 1, cambia
todos los 1+ por 3+:

=PROMEDIO(INDIRECTO(CONCATENAR("C",3+(FILA(A1)-1)*6,":C",3+(FILA(A1)-1)*6+6-1)))

Haz varias pruebas y comentas.

Saludos.



"Edo" escribió:


Qusiera saber sialguin me puedria comentar como hacer promedios cada "x"
numero de filas, es decir:

por ejemplo

Celda B1 =PROMEDIO(A1:A5)
Celda B2 =PROMEDIO(A6:A10)
Celda B3 =PROMEDIO(A11:A15)
Celda B4 =PROMEDIO(A16:A20)
...
...
etc.

si alguien me podria ayudar se lo agradeceria.
Respuesta Responder a este mensaje
#2 Edo
19/07/2007 - 03:52 | Informe spam
Antes que nada

Saludos David y muchas gracias.

Efectivamente la formula

=PROMEDIO(INDIRECTO(CONCATENAR("A",1+(FILA(A1)-1)*5,":A",1+(FILA(A1)-1)*5+5-1)))

fue la que me dio los resultados que esperaba, hice algunos calculos y luego
los comprobe, y dieron el mismo valor.

De nuevo muchas gracias y me has sacado de un apuro grandisimo ya que estoy
trabajando con cerca de 520,000 filas, y como veras hubiera sido muy
complicado hacerlo de otra manera.

PD. Si quisiera sacar igual nose la desviacion estandar o alguna otra
funcion, de la misma manera en "x" numero de filas, podria usar esta misma
formula, solo cambiando la funcion PROMEDIO por alguna otra?
Respuesta Responder a este mensaje
#3 KL
19/07/2007 - 08:44 | Informe spam
Hola chicos,

"Edo" wrote in message
news:
Antes que nada

Saludos David y muchas gracias.

Efectivamente la formula

=PROMEDIO(INDIRECTO(CONCATENAR("A",1+(FILA(A1)-1)*5,":A",1+(FILA(A1)-1)*5+5-1)))

fue la que me dio los resultados que esperaba, hice algunos calculos y
luego
los comprobe, y dieron el mismo valor.



Suponiendo que los valores estan la columna [A:A] y empiezan desde la fila
[1:1]...

Opcion1. No volatil (arrastrar hacia abajo)

=PROMEDIO(INDICE(A:A;(FILA(A1)-1)*5+1):INDICE(A:A;FILA(A1)*5))

Opcion2. Volatil (arrastrar hacia abajo)

=PROMEDIO(DESREF($A$1;(FILA(A1)-1)*5;;5))

Saludos,
KL
Respuesta Responder a este mensaje
#4 David
19/07/2007 - 18:32 | Informe spam
Si es posible.

La función Indirecto(..) te devuelve un rango, el cual puedes aplicar a
cualquier función estadística que lo requiera. Esto también sucede con
DesRef(..), como sugiere KL en la última fórmula de su propuesta.
Considérala. Es mucho más corta.



"Edo" escribió:

Antes que nada

Saludos David y muchas gracias.

Efectivamente la formula

=PROMEDIO(INDIRECTO(CONCATENAR("A",1+(FILA(A1)-1)*5,":A",1+(FILA(A1)-1)*5+5-1)))

fue la que me dio los resultados que esperaba, hice algunos calculos y luego
los comprobe, y dieron el mismo valor.

De nuevo muchas gracias y me has sacado de un apuro grandisimo ya que estoy
trabajando con cerca de 520,000 filas, y como veras hubiera sido muy
complicado hacerlo de otra manera.

PD. Si quisiera sacar igual nose la desviacion estandar o alguna otra
funcion, de la misma manera en "x" numero de filas, podria usar esta misma
formula, solo cambiando la funcion PROMEDIO por alguna otra?

email Siga el debate Respuesta Responder a este mensaje
Ads by Google
Help Hacer una preguntaRespuesta Tengo una respuesta
Search Busqueda sugerida