contar elementos

Puedes hacerlo con una tabla dinamica o con contar.si.


"fredy" escribió en el mensaje
news:

hola grupo! tengo la siguient situacion:
tengo una hoja con 10000 registros que en uno de sus campos tiene codigos
del 1 al 45 quisiera contar los que tienen ciertos codigos ( son 22
codigos,
distribuidos del 1 al 45)

como lo podria hacer?

muchas gracias

Hola fredy,

Suponiendo que los codigos estan en la columna [A]...

1) si quieres contar las ocurrencias de un codigo a la vez, usa la funcion
CONTAR.SI:

=CONTAR.SI(A:A;5)

o bien

=CONTAR.SI(A:A;B1)
donde [B1] contiene el numero de codigo

2) si son varios codigos a la vez...

a. puedes usar la funcion SUMAPRODUCTO combinada con la CONTAR.SI y una
matriz fija:

=SUMAPRODUCTO(CONTAR.SI(A2:A10000;{2\5\10\13\14\20\22}))
esta ademas tolera todo tipo de valores (como logicos, errores, texto)

b. puedes usar la funcion SUMAPRODUCTO combinada con matriz fija:

=SUMAPRODUCTO(--(A2:A10000={2\5\10\13\14\20\22}))

c. puedes usar la funcion SUMAPRODUCTO combinada con la CONTAR.SI y una
matriz dinamica:

=SUMAPRODUCTO(CONTAR.SI(A2:A10000;E4:E10))

d. puedes usar la funcion SUM combinada con matriz dinamica dentro de una
formula MATRICIAL (se confirma con Ctrl+Shift+Enter, no solo Enter):

=SUM(--(A2:A15=G4:M4))
rango horizontal

o bien:

=SUM(--(A2:A15=TRANSPONER((E4:E10))))
rango vertical


Saludos,
KL



"fredy" wrote in message
news:

hola grupo! tengo la siguient situacion:
tengo una hoja con 10000 registros que en uno de sus campos tiene codigos
del 1 al 45 quisiera contar los que tienen ciertos codigos ( son 22
codigos,
distribuidos del 1 al 45)

como lo podria hacer?

muchas gracias