formula Subtotales

01/05/2007 - 01:21 por Johann Romero | Informe spam

Tengo la siguiente formula

=SUMAR.SI(AE6:AE9996,">0",W6:W9996)

pero cuando hago un filtro, la suma sigue siendo la misma, como puedo hacer
para que este sumar si, funcione como un subtotales con reglas, se puede
incluir en una sola formula, como veran los rangos son bastantes grandes, y
no quisiera agregar una columna mas, ya que cargaria demasiado mi archivo,
lo haria mas pesado, porque podria hacer una columna nueva, validando los
que son mayores a cero, y al final de esta, agregar Subtotales( 9, y el
resto), esto me funcionaria al hacer los filtros, pero seria toda una
columna con 10 mil datos, y formulas, recargaria mucho mi archivo y lo haria
mas lento.

Gracias.

Siga el debate

3 respuestas

Tengo una respuesta

Preguntas similare

Formula Subtotales

Leer las respuestas

#1 Héctor Miguel

01/05/2007 - 02:00 | Informe spam

hola, Johann !

Tengo la siguiente formula =SUMAR.SI(AE6:AE9996,">0",W6:W9996)
pero cuando hago un filtro, la suma sigue siendo la misma
como puedo hacer para que este sumar si, funcione como un subtotales [...]

si lo que buscas es sumar/contar SOLO celdas segun 'condicion' [pero] -> sobre un rango YA con autofiltros aplicados...
se necesita usar la funcion subtotales y 'meter' la funcion desref como su segundo argumento -?-

la siguiente propuesta es una formula 'matricial'... ya sabes, al introducirla/editarla se termina con {ctrl}+{mayus}+{enter}
=sumaproducto(w6:w9996*(si(subtotales(2,desref(ae6,fila(ae6:ae9996)-fila(ae6),0)),ae6:ae9996,0)>0))

la explicacion del 'como/porque/...' funciona esta en las siguientes conversaciones: http://tinyurl.com/l3s9k
[aunque ya las visitaste, comentabas anteriormente que no lo habias 'captado'... quizar ahora sobre tu ejemplo practico] -?-

si cualquier duda [o informacion adicional]... comentas ?
saludos,
hector.

Responder a este mensaje

#2 KL

01/05/2007 - 11:21 | Informe spam

Hola chicos,

"Héctor Miguel" wrote

si lo que buscas es sumar/contar SOLO celdas segun 'condicion' [pero] -> sobre un rango YA con autofiltros aplicados...
se necesita usar la funcion subtotales y 'meter' la funcion desref como su segundo argumento -?-

la siguiente propuesta es una formula 'matricial'... ya sabes, al introducirla/editarla se termina con {ctrl}+{mayus}+{enter}
=sumaproducto(w6:w9996*(si(subtotales(2,desref(ae6,fila(ae6:ae9996)-fila(ae6),0)),ae6:ae9996,0)>0))

- Si la formula requiere de entrada MATRICIAL, entonces SUMAPRODUCTO se puede sustituir por SUMA sin ningun problema.

- Creo que la formula ofrecida por HM se puede simplificarla y "des-matricializar":

=SUMAPRODUCTO(W6:W9996*(SUBTOTALES(4;DESREF(AE6;FILA(AE6:AE9996)-FILA(AE6);))>0))

o bien

=SUMAPRODUCTO(W6:W9996*(AE6:AE9996>0)*(SUBTOTALES(2;DESREF(AE6;FILA(AE6:AE9996)-FILA(AE6);))>0))

En todo caso comprobadlo, ya que ultimamente no ando muy fino testeando mis soluciones :-))

Saludos,
KL

Responder a este mensaje

#3 Héctor Miguel

01/05/2007 - 16:28 | Informe spam

hola, KL !

- Si la formula requiere de entrada MATRICIAL, entonces SUMAPRODUCTO se puede sustituir por SUMA sin ningun problema.
- Creo que la formula ofrecida por HM se puede simplificarla y "des-matricializar":
=SUMAPRODUCTO(W6:W9996*(SUBTOTALES(4;DESREF(AE6;FILA(AE6:AE9996)-FILA(AE6);))>0))
o bien
=SUMAPRODUCTO(W6:W9996*(AE6:AE9996>0)*(SUBTOTALES(2;DESREF(AE6;FILA(AE6:AE9996)-FILA(AE6);))>0))
En todo caso comprobadlo, ya que ultimamente no ando muy fino testeando mis soluciones :-))

tienes razon :D la propuesta 'originalmente original' usa la funcion suma en lugar de sumaproducto
hice una o dos pruebas cambiando a sumaproducto pero... me 'estorbo' la funcion si-condicional con fila(...) :-((

[en lo personal] me quedo con tu primer cambio y la agrego a mi coleccion de KL-trucos ;)
con una ligera variacion: =sumaproducto(w6:w9996,--(subtotales(4,desref(ae6,fila(ae6:ae9996)-fila(ae6),))>0))

saludos,
hector.

Siga el debate Respuesta

Responder a este mensaje

Ads by Google

Hacer una pregunta

Tengo una respuesta

Busqueda sugerida