Macro cn problemas

hola, Daniel !

Encontre ... la sgte. macro en el foro pero hay algunos inconvenientes [...]
Sin poner la clave, le doy Cancelar o enter imprime el documento.
Si le pongo cualquier clave tambien imprime el documento.
Si le pongo la clave "soloyo" o "test" ahi no imprime el documento.

=> [hasta este punto]... solo tienes ->invertida<- la condicion...
[realmente] 'le estas diciendo' que... si responde 'acertadamente'... =>cancele<= :((
[creo que] te resultara 'mas claro' en el ejemplo que pongo al final :))

Cuando le pongo una clave aparece en la ventana de dialogo la palabra que escribo
... q solo aparezca asterisco como cuando se ponen claves para q la otra persona no pueda verlo.

=> para este punto... se requiere 'diseñar' un formulario [userform] con un control 'textbox'
[en las propiedades del control, aplicas la de 'passwordchar' con 'cualquier' caracter]

solo un comentario adicional...
el evento '_beforeprint' TAMBIEN es 'disparado' cuando el usuario decide usar la 'vista preliminar de impresion'
[por lo cual] si 'desde ahi' TAMBIEN 'decide' iniciar el proceso de impresion... nuevamente 'sera inquirido' :((

saludos,
hector.
en el modulo de codigo del libro [ThisWorkbook ?] ==Private Sub Workbook_BeforePrint(Cancel As Boolean)
Select Case InputBox( _
"Indica por favor tu clave de acceso.", _
"Privilegios del impresor...")
Case "soloyo", "test"
MsgBox "Clave aceptada. Iniciando proceso..."
Case Else
MsgBox "Por favor, llama al operador correspondiente.", , _
"Clave rechazada..."
Cancel = True
End Select
End Sub

Mil gracias Hecto funciono OK y por la vista preliminar no importa ya q las
hojas estan configuradas y lista para imprimir

Saludos
Daniel Padilla Cañamero

hola, Daniel !

... funciono OK ... la vista preliminar no importa ... estan configuradas y listas para imprimir

[creo que] no estaba 'por de mas' indicarte el comportamiento del evento ;)
gracias por el 'feed-back'

saludos,
hector.

Hector una consulta mas como hago para q solo trabaje en determinadas hojas q
yo escoja gracias por tu tiempo

Daniel

hola, Daniel !

... como hago para q solo trabaje en determinadas hojas [...]

1° declaras [y 'llenas'] una matriz con los nombres de las hojas que 'requieren permiso'
2° haces un 'barrido' por las hojas seleccionadas para imprimir [comparando nombres]
3° si alguna 'es' de las que estan en la matriz... ->solicitas la clave<-

=> toma nota que en el ejemplo se compara el nombre ->en la pestaña<- de cada hoja
si el usuario le cambia de nombre... se estara 'brincando' la 'proteccion' :-((
-> a menos que protejas EL LIBRO [NO la hoja] <- ;)
=> si se le ha de 'permitir' al usuario cambiar el nombre de las hojas...
la alternativa es comparar los 'codename' de las hojas
... cambiarias la instruccion que dice: ->If Hoja.Name = HojasClave(Sig) Then<-
... para que 'diga': ->If Hoja.CodeName = HojasClave(Sig) Then<-
... y [obviamente] la matriz 'HojasClave' se habra de llenar con los 'codenames' :))

saludos,
hector.
en el modulo de codigo del libro [ThisWorkbook ?] ==Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim HojasClave, Hoja As Object, Preguntar As Boolean, Sig As Byte
HojasClave = Array("Hoja1", "Hoja3")
For Each Hoja In ActiveWindow.SelectedSheets
For Sig = LBound(HojasClave) To UBound(HojasClave)
If Hoja.Name = HojasClave(Sig) Then
Preguntar = True
Exit For
End If
Next
Next
If Not Preguntar Then Exit Sub
Select Case InputBox( _
"Indica por favor tu clave de acceso.", _
"Privilegios del impresor...")
Case "soloyo", "test"
MsgBox "Clave aceptada. Iniciando proceso..."
Case Else
MsgBox "Por favor, llama al operador correspondiente.", , _
"Clave rechazada..."
Cancel = True
End Select
End Sub