Sobre barra menu inico

Usa el siguiente código:

Private Type RECT
Left As Long
Top As Long
Right As Long
Bottom As Long
End Type

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function GetWindowRect Lib "user32" (ByVal hwnd As Long, _
lpRect As RECT) As Long


Private Sub Form_Load()
Dim rct As RECT
Dim HeightBarraTareas As Long
Dim WidthBarraTareas As Long

GetWindowRect FindWindow("Shell_TrayWnd", vbNullString), rct

HeightBarraTareas = rct.Bottom - rct.Top
WidthBarraTareas = rct.Right - rct.Left
With Screen
If HeightBarraTareas = .Height \ .TwipsPerPixelY Then
Top = 0
Else
If rct.Top = 0 Then
Top = HeightBarraTareas * .TwipsPerPixelY
Else
Top = ((.Height \ .TwipsPerPixelY) - (Height \ _
.TwipsPerPixelY) - HeightBarraTareas) * .TwipsPerPixelY
End If
End If

If WidthBarraTareas = .Width \ .TwipsPerPixelX Then
Left = 0
Else
If rct.Left = 0 Then
Left = WidthBarraTareas * .TwipsPerPixelX
Else
Left = ((.Width \ .TwipsPerPixelX) - (Width \ _
.TwipsPerPixelX) - WidthBarraTareas) * .TwipsPerPixelX
End If
End If
End With
End Sub


Saludos.

"dcr2001" wrote in message
news:

Hola a todos.

Tengo una qüestion, que no se como solucionar.

Tengo una aplicación que ha de mostrar un formulario en la parte
inferior derecha de la pantalla, pero necesito saber donde se encuentra la
barra de menus de inicio y su tamaño para posicionar el formulario justo

al

borde de esta si esta en la parte inferior o justo al borde de la pantalla
si la barra no se encuentra en la parte inferior.

Alguien sabria como saber en que lugar se encuentra la barra del menu

de

inicio y las dimensiones "Grosor" de esta.


Muchas gracias a todos.

Un saludo
David Cebrian Rodriguez
www.Logic-phone.com