Impresion con ZPL II

Dbf:

Echale un ojo a mi ejemplo "de cajón".



Saludos,

Jorge Zaldívar
Guadalajara, Jal., México
Apoya a FoxPro: Usa una copia legal.
Di "¡NO!" al _bottom-posting_.

LOCAL lcTempFile, lcQty, lcSavHead

* Initialize some variables (just for testing, these are defined elsewhere)
m.cod_artic = "ti4b"
m.articulo = "Tob. Infantiles"
m.talla = "10 al 13"
m.color = "blanco"
m.cod_upc = "601349101405"
m.cantidad = 5
m.al_paso = 1
m.gcTempDir = ADDBS (GETENV ("TEMP"))

* -
m.lcQty = ALLTRIM (STR (CEILING (m.cantidad / m.al_paso)))

WAIT WINDOW NOWAIT "Generando formato"

m.lcTempFile = m.gcTempDir + SYS(3) + ".TMP"

SET TEXTMERGE TO (m.lcTempFile) NOSHOW
SET TEXTMERGE DELIMITERS TO
SET TEXTMERGE ON

* Formato de la etiqueta
\^XA
\^FWN
\^CFR
\^FO30,25
\^FD<<m.articulo>>
\^FS

\^FO30,55
\^AUN
\^FD<<m.talla>>
\^FS

\^FO45,115
\^BUN,50,,,
\^FD<<left (m.cod_UPC, 11)>>
\^FS

\^FO370,110
\^AQB
\^FD12 pares
\^FS

\^FO370,25
\^FR
\^AQB
\^FD<<m.cod_artic>>
\^FS

\^FO325,55
IF LEN (m.color) > 7
\^ASB
ELSE
\^ATB
ENDIF
\^FD<<m.color>>
\^FS
\^PQ<<m.lcQty>>
\^XZ

SET TEXTMERGE TO
SET TEXTMERGE OFF

WAIT WINDOW NOWAIT "Imprimiendo"
m.lcSavHead = SET ("HEADINGS")
SET HEADINGS OFF
SET CONSOLE OFF
SET PRINTER TO NAME "Zebra" &&Generic/Text-Only at COM2:
TYPE (m.lcTempFile) TO PRINTER
SET PRINTER TO
SET CONSOLE ON
SET HEADINGS &lcSavHead
DELETE FILE (m.lcTempFile)
WAIT CLEAR

"Dbf" escribió en el mensaje
news:

tengo poco que aprendi a programar con fox
ahora tengo que imprimir en una zebra con codigo de barras, ya aprendi a
usar el ZPL II, pero no se como mandarlo a impresion desde fox
me pueden ayudar ???


PortalFox :: Nada corre como un zorro
http://www.portalfox.com

PortalFox - NNTP Forum Gateway